//! import "ddup.j"
library MaxBash initializer Init requires DDUniversalPack

    globals
        private constant integer        MAX_BASH                = 'A000'   //рав код скила
        private constant string         PUSH_FILE               = "Abilities\\Spells\\Human\\FlakCannons\\FlakTarget.mdl"  //эффект который висит на ударенном юните
        private constant string         ON_PUSH_FILE            = "Abilities\\Spells\\NightElf\\ThornsAura\\ThornsAuraDamage.mdl"  //эффект который будет весеть на герое после удара
        private constant string         ATTACH_POINT            = "chest"   //прикрепление эффекта к герою
        private constant real           PUSH_SPEED_START       = 300.     //начальая скорость движения
        private constant real           PUSH_SPEED_END         = 150.  //конечная скорость
        private constant real           PUSH_DEACC             = 250.    //средняя скорость
        private constant boolean        DESTROY_TREES          = true  //уничтожение деревьев (булеан - да, нет)
        private constant boolean        ALLOW_FLOATING_TEXT    = true  //создания текста с нанесенным уроном
        private constant real           FLOATING_TEXT_DURATION = 4.25  //время скока будет показываться текст
            private integer             Levels = 0
            private dd_color            Clr = Null   //цвет текста, смотри ниже настроек по уровням, если хочешь изменить
            private integer array       BashChance[8191]
            private real    array       BashDamage[8191]
            private boolean array       BashAsPerc[8191]
            private real    array       BashPRange[8191]
    endglobals
    
// ТУТ НАСТРОЙКА НА КАЖДЫЙ УРОВЕНЬ

    private function SetupMaxBash takes nothing returns nothing
        set Levels = 4

//шанс на срабатывание       

        set BashChance[1] = 15
        set BashChance[2] = 15
        set BashChance[3] = 15
        set BashChance[4] = 15
        
        set BashAsPerc[1] = true
        set BashAsPerc[2] = true
        set BashAsPerc[3] = true
        set BashAsPerc[4] = true
       
//наносимый урон... умножение от текущего урона

        set BashDamage[1] = 1.5
        set BashDamage[2] = 2.
        set BashDamage[3] = 2.5
        set BashDamage[4] = 3.

//дистанция движение юнита который по башне получил

        set BashPRange[1] = 200.
        set BashPRange[2] = 225.
        set BashPRange[3] = 250.
        set BashPRange[4] = 275.
        
//цвет текста

        set Clr = CreateColor(255, 0, 0, 225)
    endfunction
    
    private keyword MaxBashPeriod
    
    globals
        private constant real       TREES_PICK_RANGE    = 125.
        private constant real       DELAY               = THREAD_DELAY*.001
    endglobals
    
    private struct bash
        private unit u     
        private float dist   
        private float vel    
        private real acc    
        private dd_vector v   
        private integer exec 
        
        implement optional dd_pointer
        //! runtextmacro constr("create", "unit u, real rad, integer lvl")
            set this.u = u
            set this.dist = Float(lvl:BashPRange)
            set this.vel = Float(PUSH_SPEED_START)
            set this.acc = PUSH_DEACC*rsign(PUSH_SPEED_END-PUSH_SPEED_START)*DELAY
            set this.v = CreateVectorDD(GetUnitX(u), GetUnitY(u), GetUnitFlyHeight(u), rad, 0.)
            call this.SetPtrObj(u)
            call FloatLimits(this.vel, rmin(PUSH_SPEED_START, PUSH_SPEED_END), rmax(PUSH_SPEED_START, PUSH_SPEED_END), true)
            call FloatLimits(this.dist, 0., GetFloat(this.dist), true)
        //! runtextmacro endconstr()
        //! runtextmacro destr()
            call DestroyFloat(this.vel)
            call DestroyFloat(this.dist)
            call DestroyVectorDD(this.v)
            call bash.ClrPtrObj(this.u)
            set this.u = null
            set this.exec = 0
        //! runtextmacro enddestr()
        
        public method Reset takes real rad, integer lvl returns nothing
            call SetFloat(this.dist, lvl:BashPRange)
            call SetFloat(this.vel, PUSH_SPEED_START)
            call SetVDirection(this.v, rad, 0.)
        endmethod
        
        public method Push takes nothing returns boolean
            call this.vel.Add(this.acc)
            call this.dist.Sub(GetFloat(this.vel)*DELAY)
            call this.v.OffsetMove(GetFloat(this.vel)*DELAY)
            set this.exec = this.exec + 1
            call SetUnitVPos(this.u, this.v)
            return (GetFloat(this.dist) == 0.)
        endmethod
        
        public method operator victim takes nothing returns unit
            return (this.u)
        endmethod
        
        public method operator vector takes nothing returns dd_vector
            return (this.v)
        endmethod
        
        public method operator execution_count takes nothing returns integer
            return (this.exec)
        endmethod

        endstruct
    
    private function EnumDests takes nothing returns nothing
        if (GetWidgetLife(GetEnumDestructable()) > .405) then
            if (IsDestructableTree(GetEnumDestructable())) then
                call KillDestructable(GetEnumDestructable())
            endif
        endif
    endfunction
    
    private function TryClearTrees takes dd_vector v, integer count returns nothing
        if (DESTROY_TREES and QMod(count, 4) == 0) then
            call EnumDestructablesInRange(v.x, v.y, TREES_PICK_RANGE, null, function EnumDests)
        endif
    endfunction
    
    private function BashExecute takes unit u, real ang, integer lvl returns nothing
        local bash pb = bash.GetPtrObj(u)

        if (pb == Null) then
            call NewThread(THREAD_DELAY, bash.create(u, ang, lvl), callback.MaxBashPeriod, true)
        else
            call pb.Reset(ang, lvl)
        endif
    endfunction
    
    private function MaxBashPeriod takes bash b returns boolean
        if (b.Push()) then
            call PauseUnit(b.victim, false)
            call b.delete()
            return (true)
        endif
       
        call TryClearTrees(b.vector, b.execution_count)
        call DestroyEffect(AddSpecialEffect(PUSH_FILE, b.vector.x, b.vector.y))
        return (false)
    endfunction
    
    private function Conditions takes nothing returns boolean
        return ( GetRandomChance(GetUnitAbilityLevel(GetEventDamageSource(), MAX_BASH):BashChance) and IsDamageTypeMelee() and not IsUnitType(GetTriggerUnit(), UNIT_TYPE_STRUCTURE) )
    endfunction

    private function MaxBash takes nothing returns nothing
        local unit      u       = GetEventDamageSource()     
        local unit      v       = GetTriggerUnit()               
        local integer   lvl     = GetUnitAbilityLevel(u, MAX_BASH)
        local real      dmg     = 0.
        call DisableTrigger(GetTriggeringTrigger())
        if (lvl:BashAsPerc) then
            set dmg = GetEventDamage()*lvl:BashDamage
        else
            set dmg = lvl:BashDamage
        endif
        call UnitDamageTarget(u, v, dmg, true, false, ATTACK_TYPE_HERO, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_WHOKNOWS)
        call DestroyEffect(AddSpecialEffectTarget(ON_PUSH_FILE, u, ATTACH_POINT))

        if (ALLOW_FLOATING_TEXT) then
            call CreateTextTagUnit(v, "+"+I2S(round(dmg)), 10., FLOATING_TEXT_DURATION, Clr)
        endif

        call PauseUnit(v, true)
        call BashExecute(v, E_AngWidget(u, v)*DEGTORAD, lvl)
        call EnableTrigger(GetTriggeringTrigger())
        set u = null
        set v = null
    endfunction
    

    private function Init takes nothing returns nothing
        call TriggerRegisterAnyUnitDamaged(onTriggerEvent(null, function Conditions, function MaxBash))
        call SetupMaxBash()
        call DestroyEffect(AddSpecialEffect(PUSH_FILE, 0., 0.))
        call DestroyEffect(AddSpecialEffect(ON_PUSH_FILE, 0., 0.))
    endfunction

endlibrary