scope MoonRoad initializer Init
    
    globals
        private integer HeroSpellRawCode = 'A000'
        private integer DummyUnitRawCode = 'h000'
        private real MaximumSpeed = 400.00
        private real Periodic = 0.025
        private real DummyMaxHeight = 500.00
        private real StarSpeed = 200.00 * Periodic
        private string Effect = "Abilities\\Weapons\\ChimaeraLightningMissile\\ChimaeraLightningMissile.mdl"
        private attacktype AT = ATTACK_TYPE_HERO
        private damagetype DT = DAMAGE_TYPE_NORMAL
    endglobals
    
    private function constant_SpeedPerSecond takes integer level returns real
        return 28.00 + 2.00 * level
    endfunction
    
    private function constant_Radius takes integer level returns real
        return 500.00 + 100.00 * level
    endfunction
    
    private function constant_Damage takes integer level returns real
        return 100.00 + 50.00 * level
    endfunction
    
    private struct Star
        unit dummy
        real range
        real sourceX
        real sourceY
        real targetX
        real targetY
        real damage
        real angle
        boolean active
    endstruct
    
    private struct MoonRoad
        unit caster
        unit dummy
        real current_speed
        real inc_speed
        real maximum_speed
        real direction
        real radius
        real damage
        boolean active
    endstruct
    
    globals
        private MoonRoad array Data
        private Star array Data2
        private integer Count = 0
        private integer Count2 = 0
        private timer Timer = CreateTimer( )
        private timer Timer2 = CreateTimer( )
        
        private real minX
        private real maxX
        private real minY
        private real maxY
        
        private boolexpr Null
    endglobals
    
    private function ParabolaZ takes real h, real d, real x returns real
      return ( 4 * h / d ) * ( d - x ) * ( x / d )
    endfunction
    
    private function MCC takes real x, real y returns boolean
        return x > minX and y > minY and x < maxX and y < maxY
        // Credits to Shadow Daemon for this function
    endfunction
    
    private function DamageAoE takes unit c, real x, real y, real radius, real dmg returns nothing
        local group g = CreateGroup()
        local unit u
        
        call GroupEnumUnitsInRange( g, x, y, radius, Null )
        
        loop
            set u = FirstOfGroup( g )
            exitwhen u == null
            call GroupRemoveUnit( g, u )
            
            call UnitDamageTarget( c, u, dmg, false, false, AT, DT, WEAPON_TYPE_WHOKNOWS )
        endloop
        
        call DestroyGroup( g )
        set g = null
    endfunction
    
    private function OnTimer2 takes nothing returns nothing
        local Star this
        local integer i = 0
        local real x
        local real y
        local real d
        
        loop
            exitwhen i >= Count2
            set this = Data2[ i ]
            
            set x = GetUnitX( this.dummy ) + StarSpeed * Cos( this.angle )
            set y = GetUnitY( this.dummy ) + StarSpeed * Sin( this.angle )
            set d = SquareRoot( ( this.sourceX - x ) * ( this.sourceX - x ) + ( this.sourceY - y ) * ( this.sourceY - y ) )
            
            if this.active == false then
                call DamageAoE( this.dummy, x, y, 100.00, this.damage )
                call DestroyEffect( AddSpecialEffect( Effect, x, y ) )
                call RemoveUnit( this.dummy )
                
                call this.destroy( )
                set Count2 = Count2 - 1
                set Data2[ i ] = Data2[ Count2 ]
                set i = i - 1
                
                if Count2 == 0 then
                    call PauseTimer( Timer2 )
                endif
            else
                if SquareRoot( ( this.targetX - x ) * ( this.targetX - x ) + ( this.targetY - y ) * ( this.targetY - y ) ) <= 50.00 or MCC( x, y ) == false then
                    set this.active = false
                else
                    call SetUnitX( this.dummy, x )
                    call SetUnitY( this.dummy, y )
                    call SetUnitFlyHeight( this.dummy, ParabolaZ( DummyMaxHeight, this.range, d ), 0.00 )
                endif
            endif
            
            set i = i + 1
        endloop
        
    endfunction
    
    private function Add2 takes unit c, real x1, real y1, real x2, real y2, real dmg returns nothing
        local Star this = Star.create( )
        
        set this.dummy = CreateUnit( GetOwningPlayer( c ), DummyUnitRawCode, x1, y1, 0.00 )
        set this.range = SquareRoot( ( x1 - x2 ) * ( x1 - x2 ) + ( y1 - y2 ) * ( y1 - y2 ) )
        set this.angle = Atan2( y2 - y1, x2 - x1 )
        set this.damage = dmg
        set this.sourceX = x1
        set this.sourceY = y1
        set this.targetX = x2
        set this.targetY = y2
        set this.active = true
        
        if Count2 == 0 then
            call TimerStart( Timer2, Periodic, true, function OnTimer2 )
        endif
        
        set Data2[ Count2 ] = this
        set Count2 = Count2 + 1
    endfunction
    
    private function Destroy takes unit c, real x, real y, real aoe, real dmg returns nothing
        local integer max = R2I( aoe / 50.00 )
        local integer i = 0
        local integer in = 0
        local real X
        local real Y
        
        loop
            set i = i + 1
            exitwhen i > max
            
            set in = 0
            
            loop
                set in = in + 1
                exitwhen in > 12
                set X = x + ( i * 50.00 ) * Cos( ( in * 30.00 ) * bj_DEGTORAD )
                set Y = y + ( i * 50.00 ) * Sin( ( in * 30.00 ) * bj_DEGTORAD )
                call Add2( c, x, y, X, Y, dmg )
            endloop
        endloop
        
    endfunction
    
    private function OnTimer takes nothing returns nothing
        local MoonRoad this
        local integer i = 0
        local real x
        local real y
        
        loop
            exitwhen i >= Count
            set this = Data[ i ]
            
            set x = GetUnitX( this.dummy )
            set y = GetUnitY( this.dummy )
            
            if this.active == false then
                call KillUnit( this.dummy )
                call Destroy( this.caster, x, y, this.radius, this.damage)
                
                call this.destroy( )
                set Count = Count - 1
                set Data[ i ] = Data[ Count ]
                set i = i - 1
                
                if Count == 0 then
                    call PauseTimer( Timer )
                endif
            else
                set this.current_speed = this.current_speed + ( this.inc_speed * Periodic )
                call SetUnitMoveSpeed( this.dummy, this.current_speed )
                
                if GetUnitCurrentOrder( this.dummy ) != 851971 then
                    call IssuePointOrderById( this.dummy, 851971, x + 1000.00 * Cos( this.direction ), y + 1000.00 * Sin( this.direction ) )
                endif
                
                if MCC( x, y ) == false or this.current_speed >= this.maximum_speed then
                    set this.active = false
                endif
            endif
            
            set i = i + 1
        endloop
        
    endfunction
    
    private function Add takes unit c returns nothing
        local MoonRoad this = MoonRoad.create( )
        local integer lvl = GetUnitAbilityLevel( c, HeroSpellRawCode )
        
        set this.caster = c
        set this.dummy = CreateUnit( Player( 15 ), GetUnitTypeId( c ), 0.00, 0.00, GetUnitFacing( c ) )
        
        call SetUnitPathing( this.dummy, false )
        call SetUnitX( this.dummy, GetUnitX( c ) )
        call SetUnitY( this.dummy, GetUnitY( c ) )
        call SetUnitColor( this.dummy, GetPlayerColor( GetOwningPlayer( c ) ) )
        call UnitAddAbility( this.dummy, 'Aloc' )
        
        set this.current_speed = GetUnitMoveSpeed( c )
        set this.inc_speed = constant_SpeedPerSecond( lvl )
        set this.maximum_speed = MaximumSpeed
        set this.direction = GetUnitFacing( c ) * bj_DEGTORAD
        set this.radius = constant_Radius( lvl )
        set this.damage = constant_Damage( lvl )
        set this.active = true
        
        if Count == 0 then
            call TimerStart( Timer, Periodic, true, function OnTimer )
        endif
        
        set Data[ Count ] = this
        set Count = Count + 1
    endfunction
    
    private function Dummy takes nothing returns boolean
        return true
    endfunction
    
    private function Cast takes nothing returns boolean
        if GetSpellAbilityId( ) == HeroSpellRawCode then
            call Add( GetTriggerUnit() )
        endif
        
        return false
    endfunction
    
    private function Init takes nothing returns nothing
        local trigger t = CreateTrigger( )
        
        call TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_UNIT_SPELL_EFFECT )
        call TriggerAddCondition( t, Condition( function Cast ) )
        
        set minX = GetRectMinX( bj_mapInitialPlayableArea )
        set maxX = GetRectMaxX( bj_mapInitialPlayableArea )
        set minY = GetRectMinY( bj_mapInitialPlayableArea )
        set maxY = GetRectMaxY( bj_mapInitialPlayableArea )
        
        set Null = Condition( function Dummy )
        
        set t = null
    endfunction
    
endscope