scope Regen initializer ini{
    
    include "cj_types_priv.j"
    
    define{
        private SpellId = 'A000'
        private TimeInitial = 10
        private TimeDecreaseLvl = 1
        private RegenAmountLvl = 1
        private EffectString = ""
    }
    
    private bool filter(){
        return GetUnitAbilityLevel(GetFilterUnit(), SpellId) > 0
    }

    private hashtable hash = InitHashtable()
    private filterfunc fltr

    private void Enum(){
        unit u = GetEnumUnit()
        int i = LoadInteger(hash, GetHandleId(u), 0)
        SaveInteger(hash, GetHandleId(u), 0, i - 1)
        if (i < 0) { i = 0 }
        if (i == 0){
            SetWidgetLife(u, GetWidgetLife(u) + GetUnitState(u, UNIT_STATE_MAX_LIFE) * .01 * GetUnitAbilityLevel(u, SpellId) * RegenAmountLvl)
            DestroyEffect(AddSpecialEffectTarget(EffectString, u, "chest,mount"))
        }
        u = null
    }

    private void Actions(){
        group g = CreateGroup()
        GroupEnumUnitsInRect(g, bj_mapInitialPlayableArea, fltr)
        ForGroup(g, function Enum)
        DestroyGroup(g)
        g = null
    }
    
    private bool AttackConditions(){
        return GetUnitAbilityLevel(GetTriggerUnit(), SpellId) > 0
    }
    
    private void AttackActions(){
        unit u = GetTriggerUnit()
        SaveInteger(hash, GetHandleId(u), 0, TimeInitial - GetUnitAbilityLevel(u, SpellId) * TimeDecreaseLvl)
        u = null
    }
    
    private void ini(){
        TimerStart(CreateTimer(), .25, true, function Actions)
        fltr = Filter(function filter)
        trigger t = CreateTrigger()
        int  i = 0
        whilenot (i == 15){
            TriggerRegisterPlayerUnitEvent(t, Player(i), EVENT_PLAYER_UNIT_ATTACKED, null)
            i++
        }
        TriggerAddAction(t, function AttackActions)
        TriggerAddCondition(t, Condition(function AttackConditions))
        t = null
    }

}