scope OmniSplash initializer Init {
    include "cj_types_priv.j"
    //===========================================================================
    private hashtable h=InitHashtable()
    //===========================================================================
    define {
        private SPELL=              'A000'
        //абилка
        private EFFECT_cast=        "Abilities\\Spells\\Human\\Polymorph\\PolyMorphTarget.mdl"
        //эффект при перемещение на кастере
        private EFFECT_targ=        "Abilities\\Spells\\Orc\\FeralSpirit\\feralspirittarget.mdl"
        //еффект при перемещении на цели
        private EFFECT_patch_cast=  "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile.mdl"
        //эффект на время действия заклинания
        private EFFECT_to=          "weapon"
        //куда прицепить его
        private times=              50
        //кол-во прыжков
        private times_inc=          5
        //повышение за уровень
        private damage=             0.
        //урон
        private damage_inc=         80.
        //повышение урона за уровень
        private range=              75.
        //дистанция м/у целей и кастером
        private RANGE=              500.
        private periodic=           0.07
        //период прыжков
        private animation=          "Attack Walk Stand Spin"
        //анимация при каждом прыжке
        private AttackType=         ATTACK_TYPE_CHAOS
        private DamageType=         DAMAGE_TYPE_UNIVERSAL
        private WeaponType=         WEAPON_TYPE_WHOKNOWS
        //вид урона
    //===========================================================================
        private move(cast,targ)={
            real x1=GetUnitX(targ)
            real y1=GetUnitY(targ)
            real a=GetRandomReal(0,360)
            SetUnitX(cast,x1+range*Cos(a))
            SetUnitY(cast,y1+range*Sin(a))
            DestroyEffect(AddSpecialEffectTarget(EFFECT_cast,cast,"origin"))
            DestroyEffect(AddSpecialEffectTarget(EFFECT_targ,targ,"origin"))
            IssueTargetOrder( cast, "Attack", targ)
            SetUnitAnimation(cast,animation)
            //SetUnitAnimation(targ,"death")
        }
    //===========================================================================
        private GG(cast,targ,g,dmg)={
            bool b=false
            GroupEnumUnitsInRange( g, GetUnitX(targ), GetUnitY(targ), RANGE,null)
            loop
                targ=GroupPickRandomUnit(g)
                if IsUnitVisible(targ,GetOwningPlayer(cast))==true and IsPlayerEnemy(GetOwningPlayer(targ), GetOwningPlayer(cast)) == true and IsUnitDeadBJ(targ) == false and IsUnitType(targ, UNIT_TYPE_STRUCTURE) == false then
                    b=true
                    UnitDamageTarget(cast,targ,dmg,true,false,AttackType,DamageType,WeaponType)
                endif
                GroupRemoveUnit(g,targ)
                exitwhen b==true or targ==null
            endloop
            }
    //===========================================================================
        private FLUSH(e,cast,i,t)={
            SetUnitAnimation(cast,"Stand")
            IssueImmediateOrder(cast,"stop")
            DestroyEffect(e)
            DestroyTimer(t)
            FlushChildHashtable(h,i)
            SetUnitInvulnerable(cast,false)
        }
    }
    //===========================================================================
    private bool cond(){
        return GetSpellAbilityId() == SPELL
    }
    //===========================================================================
    private void action(){
        timer t=GetExpiredTimer()
        int i=GetHandleId(t)
        int time=LoadInteger(h,i,2)
        real dmg=LoadReal(h,i,3)
        unit cast=LoadUnitHandle(h,i,0),targ=LoadUnitHandle(h,i,1)
        effect e=LoadEffectHandle(h,i,4)
        
        if time>0 then
            group g=CreateGroup()
            move(cast,targ)
            GG(cast,targ,g,dmg)
            if targ == null then
                FLUSH(e,cast,i,t)
            else
                SaveInteger(h,i,2,time-1)
                
                SaveUnitHandle(h,i,1,targ)
            endif
        else
            FLUSH(e,cast,i,t)
        endif
        DestroyGroup(g)
        g=null
        t=null
        cast=null
        targ=null
        e=null
    }
    //===========================================================================
    private void main(){
        unit cast=GetTriggerUnit(),targ=GetSpellTargetUnit()
        timer t=CreateTimer()
        int i=GetHandleId(t),level=GetUnitAbilityLevel(cast,SPELL)
        effect e=AddSpecialEffectTarget(EFFECT_patch_cast,cast,EFFECT_to)
        SaveUnitHandle(h,i,0,cast)
        SaveUnitHandle(h,i,1,targ)
        SaveInteger(h,i,2,times+times_inc*level)
        SaveReal(h,i,3,damage+damage_inc*level)
        SaveEffectHandle(h,i,4,e)
        //SetUnitInvulnerable(cast,true)
        TimerStart(t, periodic, true, function action)
        cast=null
        targ=null
        t=null
        e=null
    }
    //===========================================================================
    private void Init(){
        trigger t=CreateTrigger()
        int index=0
        loop
            exitwhen index ==15
            TriggerRegisterPlayerUnitEvent(t, Player(index), EVENT_PLAYER_UNIT_SPELL_CAST, null)
            index ++
        endloop
        TriggerAddCondition( t, Condition( function cond ) )
        TriggerAddAction( t, function main )
        t=null
    }
}