Прошу помочь сделать один интерестный (помоему сложный скилл):

scope asd initializer Init {
include "cj_types_priv.j"
    define{
        private SPELL='AHtb'
        //айди основы
        private DUMMY='h000'
        //айди даммика
        private SPEED=13
        //скорость даммика
        private periodic=0.025
        //период движения даммика
        private duration=0.03
        //время стана * статы
        private duration_stat=GetHeroAgi
        //умножаме время стана на ловкость (еще варианты Agi/Str/Int)
        private EFFECT="Abilities\\Spells\\Human\\Thunderclap\\ThunderclapTarget.mdl"
        //эффект на цель при стане
        private attach="overhead"
        //куда цепляем эфеект
        private multiply=10
        //урон * статы
        private multiply_stat=GetHeroStr
        //умножаме урон от стана на силу (еще варианты Agi/Str/Int)
    }
    private hashtable hash=InitHashtable()
    private int array Data
    private int Total = 0
    private void end_stun(){
        timer t=GetExpiredTimer()
        int i=GetHandleId(t)
        unit tt=LoadUnitHandle(hash,i,0)
        effect e=LoadEffectHandle(hash,i,1)
        DestroyEffect(e)
        FlushChildHashtable(hash,i)
        DestroyTimer(t)
        PauseUnit(tt,false)
        t=null
        tt=null
        e=null
    }
    private void action_stun(unit tt,real d){
        timer t=CreateTimer()
        int i=GetHandleId(t)
        effect e=AddSpecialEffectTarget(EFFECT,tt,attach)
        PauseUnit(tt,true)
        SaveUnitHandle(hash,i,0,tt)
        SaveEffectHandle(hash,i,1,e)
        TimerStart(t,d,false,function end_stun)
        e=null
        t=null
    }
    //===============================================
    private struct Motion {
        unit u=null
        unit t=null
        unit d=null
        static method move takes nothing returns nothing
            Motion dat
            int i=0,str,agi
            real x,y,x1,y1,a,d,damage
            loop
                exitwhen i >= Total
                dat = Data[i]
                x=GetUnitX(dat.d)
                x1=GetUnitX(dat.t)
                y=GetUnitY(dat.d)
                y1=GetUnitY(dat.t)
                a=Atan2(y1-y,x1-x)
                d=SquareRoot((x1-x)*(x1-x)+(y1-y)*(y1-y))
                str=multiply_stat(dat.u, true)
                agi=duration_stat(dat.u, true)
                SetUnitX(dat.d,x+SPEED*Cos(a))
                SetUnitY(dat.d,y+SPEED*Sin(a))
                SetUnitFacing(dat.d,a*57.2957795)
                if d < SPEED then
                    damage=multiply*I2R(str)
                    KillUnit(dat.d)
                    UnitDamageTarget(dat.u,dat.t,damage,true,false,ATTACK_TYPE_MELEE,DAMAGE_TYPE_UNIVERSAL ,WEAPON_TYPE_WHOKNOWS)
                    Total --
                    Data[i] = Data[Total]
                    i --
                    action_stun(dat.t,agi*duration)
                    debug BJDebugMsg("dmg - "+R2S(damage) )
                    debug BJDebugMsg("stun time - "+R2S(agi*duration) )
                    Motion.destroy(dat)
                    
                endif
                i ++
            endloop
        endmethod
    
    //===============================================
        static method create takes nothing returns Motion
            Motion dat = Motion.allocate()
            Data[Total] = dat
            Total ++
            return dat
        endmethod
    
    //===============================================
        method onDestroy takes nothing returns nothing
            .u=null
            .t=null
            .d=null
        endmethod
    }
    //===============================================
    private bool cond(){return GetSpellAbilityId()==SPELL}
    //===============================================
    private void action(){
        Motion a=Motion.create()
        a.u=GetTriggerUnit()
        a.t=GetSpellTargetUnit()
        a.d=CreateUnit(GetOwningPlayer(a.u),DUMMY, GetUnitX(a.u),GetUnitY(a.u),57.2957795*Atan2(GetUnitY(a.t)-GetUnitY(a.u),GetUnitX(a.t)-GetUnitX(a.u)​))
    }
    //===============================================
    private void Init(){
        trigger gg= CreateTrigger(  )
        integer index=0
        TimerStart(CreateTimer(),periodic,true,function Motion.move)
        while(index==0) {
            TriggerRegisterPlayerUnitEvent(gg, Player(index), EVENT_PLAYER_UNIT_SPELL_CAST, null)
            index ++
        }
        TriggerAddCondition( gg, Condition( function cond ) )
        TriggerAddAction( gg, function action )
        gg=null
    }
}