scope FireShield initializer Init{
    include "cj_types_priv.j"
    define{
        private SpellId         ='A000'
        private SpellId2        ='A001'
        private ShieldDuration  =10.
        private Cooldown        =25.
        private AoEDamage       =300.
        private Duration        =10.
        private Effect          ="Abilities\\Spells\\NightElf\\Immolation\\ImmolationTarget.mdl"
        private Effect2         ="Environment\\LargeBuildingFire\\LargeBuildingFire2.mdl"
        private Effect3         ="Abilities\\Spells\\Human\\MarkOfChaos\\MarkOfChaosTarget.mdl"
    }
    private unit CAST
    private real DMG
    private hashtable Hash=InitHashtable()
    private struct Dota{
        unit cast,targ
        real d,dmg
        effect e
        static method onAction takes void returns void
            timer t = GetExpiredTimer()
            thistype r= GetTimerData(t)
            if GetWidgetLife(r.targ) > 0.405 and r.d>0
                r.d-=0.5
                UnitDamageTarget(r.cast, r.targ, r.dmg , false, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_UNKNOWN, null)  
            else
                DestroyEffect(r.e)
                ReleaseTimer(t)
            endif
            t=null
        endmethod
        static method onCreate takes unit cast,unit targ,real dmg returns thistype
            thistype r = thistype.create()
            timer t = NewTimer()
            r.cast=cast
            r.targ=targ
            r.d=Duration
            r.dmg=dmg/2
            r.dmg/=r.d
            r.e=AddSpecialEffectTarget(Effect2,r.targ,"origin")
            SetTimerData(t, r)
            TimerStart(t, 0.5, true, function thistype.onAction)
            t = null
        return r
        endmethod
    }
    private void Check(){
        timer t=GetExpiredTimer()
        int i=GetHandleId(t)
        unit u=LoadUnitHandle(Hash,i,0)
        real heal=LoadReal(Hash,i,1)
        SetWidgetLife(u,GetWidgetLife(u)+heal)
        UnitRemoveAbility(u,SpellId2)
        DestroyTimer(t)
        FlushChildHashtable(Hash,i)
        t=null
        u=null
    }
    private bool onDota(){
        unit u=GetFilterUnit()
        if IsUnitEnemy(CAST, GetOwningPlayer(u)) and GetWidgetLife(u) > 0.405 and not IsUnitType(u, UNIT_TYPE_STRUCTURE) and not IsUnitType(u, UNIT_TYPE_MECHANICAL) then 
            Dota.onCreate(CAST,u,DMG)
            DestroyEffect(AddSpecialEffect(Effect3,GetUnitX(u),GetUnitY(u)))
        endif
        return false
    }       
    private bool onTakeDamage(){
        trigger t=GetTriggeringTrigger()
        int i=GetHandleId(t)
        unit u=GetTriggerUnit()
        real dmg=GetEventDamage(),d=LoadReal(Hash,i,0)
        debug ClearTextMessages()
        debug BJDebugMsg("Take Damage... [ |c009B9BFF"+R2S(dmg)+"|r ] | [ |c00FF9B9B"+R2S(d)+"|r ]")
        if dmg>0 and d>dmg
            SaveReal(Hash,i,0,d-dmg)
            SaveReal(Hash,i,100,LoadReal(Hash,i,100)+dmg)
            timer t2=CreateTimer()
            int i2=GetHandleId(t2)
            SaveUnitHandle(Hash,i2,0,u)
            SaveReal(Hash,i2,1,dmg)
            UnitAddAbility(u,SpellId2)
            TimerStart(t2,0.,false,function Check)
        else
            CAST=u
            DMG=LoadReal(Hash,i,100)
            GroupEnumUnitsInRange(bj_lastCreatedGroup, GetUnitX(u), GetUnitY(u), AoEDamage, Filter(function onDota)) 
            DestroyTrigger(t)
            DestroyEffect(LoadEffectHandle(Hash,i,1))
            FlushChildHashtable(Hash,i)
        endif
        t=null
        u=null
        t2=null
        return false
    }
    private void CheckTimer(){
        timer t=GetExpiredTimer()
        int i=GetHandleId(t)
        trigger t2=LoadTriggerHandle(Hash,i,0)
        if t2!=null
            DestroyTrigger(t2)
            DestroyEffect(LoadEffectHandle(Hash,GetHandleId(t2),1))
            FlushChildHashtable(Hash,GetHandleId(t2))
        endif
        FlushChildHashtable(Hash,i)
        t=null
        t2=null
    }
    private void TakeDamage(unit u,int Level){
        trigger t=CreateTrigger()
        int i=GetHandleId(t)
        SaveReal(Hash,i,0,120+120*Level)
        TriggerRegisterUnitEvent( t, u, EVENT_UNIT_DAMAGED )
        TriggerAddCondition(t,Condition(function onTakeDamage))
        timer t2=CreateTimer()
        int i2=GetHandleId(t2)
        SaveTriggerHandle(Hash,i2,0,t)
        SaveEffectHandle(Hash,i,1,AddSpecialEffectTarget(Effect,u,"origin"))
        TimerStart(t2,ShieldDuration,false,function CheckTimer)
        t=null
        t2=null
    }
    private struct Timer{
    unit u
        static method onAction takes void returns void
            timer t = GetExpiredTimer()
            thistype r= GetTimerData(t)
            if GetWidgetLife(r.u) > 0.405
                TakeDamage(r.u,GetUnitAbilityLevel(r.u,SpellId))
            endif
            t=null
        endmethod
        static method onCreate takes unit caster returns thistype
            thistype r = thistype.create()
            timer t = NewTimer()
            r.u=caster
            SetTimerData(t, r)
            TimerStart(t, Cooldown, true, function thistype.onAction)
            t = null
        return r
        endmethod
    }
    private bool Cond(){
        unit u=GetTriggerUnit()
        if GetLearnedSkill()==SpellId and GetUnitAbilityLevel(u,SpellId)==1
            Timer.onCreate(u)
            TakeDamage(u,GetUnitAbilityLevel(u,SpellId))
        endif
        u=null
        return false
    }
    private void Init(){
        int i=0
        trigger t=CreateTrigger()
        do{
            TriggerRegisterPlayerUnitEvent(t, Player(i), EVENT_PLAYER_HERO_SKILL, null)
        }whilenot(i++==15)
        TriggerAddCondition(t,Condition(function Cond))
        t=null
        
    }
}