function Trig_DeathGrip_Conditions takes nothing returns boolean
        return GetSpellAbilityId() == 'A000'
endfunction

function SR takes real xa, real ya, real xb, real yb returns real
return SquareRoot((xa-xb)*(xa-xb)+(ya-yb)*(ya-yb))
endfunction

function Trig_DeathGrip_Actions2 takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit u = LoadUnitHandle(udg_Hash,id,0)
    local unit d = LoadUnitHandle(udg_Hash,id,1)
    local unit c = LoadUnitHandle(udg_Hash,id,2)
    local lightning l = LoadLightningHandle(udg_Hash,id,3)
    local real Angle
    local real x = GetUnitX(d)
    local real y = GetUnitY(d)
    local real x1 = GetUnitX(u)
    local real y1 = GetUnitY(u)
    local real h = GetUnitFlyHeight(d)
  if(SR(x,y,x1,y1) > 26)then
    set Angle= Atan2(y-y1,x-x1)
    call SetUnitX(d,GetUnitX(d)-21.*Cos(Angle))
    call SetUnitY(d,GetUnitY(d)-21.*Sin(Angle))
    call SetUnitX(c,GetUnitX(d))
    call SetUnitY(c,GetUnitY(d))
    call SetUnitFacing(d,Angle*bj_RADTODEG)
    call SetUnitFlyHeight(c,h,GetUnitFlyHeight(c))
    call MoveLightningEx(l,false,x1,y1,GetUnitFlyHeight(u)+50,x,y,h+50)
  else
    call RemoveUnit(c)
    call FlushChildHashtable(udg_Hash,id)
    call DestroyTimer(t)
    call DestroyLightning(l)
    call SetUnitFlyHeight(d,0,h)
    call PauseUnit(d,false)
  endif
  set u = null
  set d = null
  set c = null
  set t = null
  set l = null
endfunction

function Trig_DeathGrip_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local unit d = GetSpellTargetUnit()
    local unit c = CreateUnit(GetOwningPlayer(u),'h000',GetUnitX(d),GetUnitY(d),GetUnitFacing(d))
    local timer t = CreateTimer()
    local integer id = GetHandleId(t)
    local real h = GetUnitFlyHeight(d)
    local lightning l = AddLightningEx("CLPB",false,GetUnitX(u), GetUnitY(u),GetUnitFlyHeight(u)+50,GetUnitX(d),GetUnitY(d),h+50)
    call SetLightningColor(l, 0.40, 0.15, 1.00, 1 )
    call SaveUnitHandle(udg_Hash,id,0,u)
    call SaveUnitHandle(udg_Hash,id,1,d)
    call SaveUnitHandle(udg_Hash,id,2,c)
    call SaveLightningHandle(udg_Hash,id,3,l)
    call UnitAddAbility(d,'Arav')
    call SetUnitFlyHeight(d,h+150,h)
    call UnitRemoveAbility(d,'Arav')
    call PauseUnit(d,true)
    call TimerStart(t,.025,true,function Trig_DeathGrip_Actions2)
    set u = null
    set d = null
    set c = null
    set l = null
endfunction

//===========================================================================
function InitTrig_DeathGrip takes nothing returns nothing
    set gg_trg_DeathGrip = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_DeathGrip, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_DeathGrip, Condition( function Trig_DeathGrip_Conditions ) )
    call TriggerAddAction( gg_trg_DeathGrip, function Trig_DeathGrip_Actions )
endfunction