scope Shields

    globals
    private constant string EFFECT_BOOM = "Abilities\\Spells\\Orc\\WarStomp\\WarStompCaster.mdl"
    private trigger array Trigger
    private timer array Timer
    private real array K
    private real array DAMAGE
    private integer array Iuse
    private unit array CASTER
    private unit array TARGET
    private integer N = 0
    private real dmg
    endglobals
    
    define {
    private SPELL = 'A000' // применяемая способность
    private BAFF = 'BNms' // Накладываемый бафф
    private AREA = 350.0 // Область нанесения урона
    private DMG_REDUC = { // Коэффициент уменьшения урона на лвл
                        set K[N] = 0.2*lvl
                        if lvl == 4 then
                            set K[N] = K[N] - 0.05 //т.к. он будет 80%, а надо 75, то отнимаем
                        elseif lvl == 5 then
                            set K[N] = K[N] - 0.1 //т.к. он будет 100%, а надо 90, то отнимаем
                        endif
                        }
    private IGN_DAMAGE = 0.0 //Этот и меньше урона не будут засчитываться.
    private N_DEF = 5 // Кол-во защит от ударов. Можно использовать lvl (уровень способности)
    private TIME_OUT = 15.0 // Время жизни щита. Можно использовать lvl
    private IN_X = 0.8 // Множитель. При каждом срабатывании щита его сила умножается на это число
    private K_DAMAGE = 0.2 // Коэффициент урона для взрыва от спасенного/доп. урона
    }
    
// Нанесения урона
private function Trig_Shield_Filter takes nothing returns boolean
    return bj_groupRandomCurrentPick != GetFilterUnit() and GetUnitState(GetFilterUnit(), UNIT_STATE_LIFE) > 0.00 and IsUnitEnemy(GetFilterUnit(), bj_forceRandomCurrentPick) and IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == false
endfunction
private function Trig_Shield_Group takes nothing returns nothing
    call UnitDamageTarget ( bj_groupRandomCurrentPick, GetEnumUnit(), dmg, true, false, ATTACK_TYPE_MAGIC, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_WHOKNOWS )
endfunction
private function Trig_Shield_Damage takes integer i, unit u returns nothing
    group g = CreateGroup()
    boolexpr f = Condition (function Trig_Shield_Filter)
    real x = GetUnitX(u)
    real y = GetUnitY(u)
    set bj_forceRandomCurrentPick = GetOwningPlayer(CASTER[i])
    set bj_groupRandomCurrentPick = u
    call GroupEnumUnitsInRange ( g, x, y, AREA, f )
    set bj_groupRandomCurrentPick = CASTER[i]
    set dmg = DAMAGE[i]*K_DAMAGE
    call ForGroup(g, function Trig_Shield_Group )
    call DestroyEffect ( AddSpecialEffect(EFFECT_BOOM, x, y) )
    call DestroyGroup(g)
    call DestroyBoolExpr (f)
    set g = null
    set f = null
endfunction
// Таймер для удаления
private function Trig_Shield_Timer takes nothing returns nothing
    integer i = 1
    whilenot ( GetExpiredTimer() == Timer[i] ) { i++ }
    if TimerGetElapsed(Timer[i]) != 2.0 then
        call TriggerClearActions ( Trigger[i] )
        call TriggerClearConditions ( Trigger[i] )
        call DisableTrigger( Trigger[i] )
        if TimerGetElapsed(Timer[i]) != 0.0 then
            call Trig_Shield_Damage ( i, TARGET[i] )
        endif
        call TimerStart ( Timer[i], 2.0, false, function Trig_Shield_Timer )
    else
        call DestroyTrigger ( Trigger[i] )
        call DestroyTimer ( Timer[i] )
        // null
        if i != N {
            set Trigger[i] = Trigger[N]
            set Timer[i] = Timer[N]
            set CASTER[i] = CASTER[N]
            set K[i] = K[N]
            set Iuse[i] = Iuse[N]
            set DAMAGE[i] = DAMAGE[N]
            set TARGET[i] = TARGET[N]
            }
        set Trigger[N] = null
        set Timer[N] = null
        set CASTER[N] = null
        set K[N] = 0.0
        set DAMAGE[N] = 0.0
        set Iuse[N] = 0
        set TARGET[N] = null
        N--
    endif
endfunction
// для противника
private function Trig_Shield_Conditions_Enemy takes nothing returns boolean
    if GetEventDamage() > IGN_DAMAGE then
        return true
    endif
    return false
endfunction
// Для наложения на Союзника
private function Trig_Shield_Conditions_Ally takes nothing returns boolean
    integer i
    real hp = GetUnitState(GetTriggerUnit(), UNIT_STATE_LIFE )
    if GetEventDamage() >= hp then
        set i = 1
        whilenot ( GetTriggeringTrigger() == Trigger[i] ) { i++ }
        call SetUnitState( GetTriggerUnit(), UNIT_STATE_LIFE, hp + GetEventDamage()*K[i] )
        set DAMAGE[i] = DAMAGE[i] + GetEventDamage()*K[i]
        set K[i] = K[i]*IN_X
        Iuse[i]--
        if Iuse[i] == 0 {
            call Trig_Shield_Damage ( i, GetTriggerUnit() )
            call UnitRemoveAbility( GetTriggerUnit(), BAFF )
            call TimerStart(Timer[i], 0.0, false, function Trig_Shield_Timer )
        }
        return false
    endif
    if GetEventDamage() > IGN_DAMAGE then
        return true
    endif
    return false
endfunction
private function Trig_Shield_Actions_Ally takes nothing returns nothing
    integer i = 1
    real hp = GetUnitState(GetTriggerUnit(), UNIT_STATE_LIFE )
    whilenot ( GetTriggeringTrigger() == Trigger[i] ) { i++ }
    if IsUnitAlly(CASTER[i], GetOwningPlayer(GetTriggerUnit())) then
        call SetUnitState( GetTriggerUnit(), UNIT_STATE_LIFE, hp + GetEventDamage()*K[i] )
    else
        call DisableTrigger(Trigger[i])
        call UnitDamageTarget ( GetEventDamageSource(), GetTriggerUnit(), GetEventDamage()*K[i], true, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_UNIVERSAL, WEAPON_TYPE_WHOKNOWS )
        call EnableTrigger(Trigger[i])
    endif
    set DAMAGE[i] = DAMAGE[i] + GetEventDamage()*K[i]
    set K[i] = K[i]*IN_X
    Iuse[i]--
    if Iuse[i] == 0 {
        call Trig_Shield_Damage ( i, GetTriggerUnit() )
        call UnitRemoveAbility( GetTriggerUnit(), BAFF )
        call TimerStart(Timer[i], 0.0, false, function Trig_Shield_Timer )
    }
endfunction
    //===
private function Trig_Shield_Actions takes nothing returns nothing
    integer lvl = GetUnitAbilityLevel( GetTriggerUnit(), SPELL )
    integer i = 1
    unit u = GetSpellTargetUnit()
    whilenot ( u == TARGET[i] or i > N ) { i++ }
    set u = null
    if i <= N then
        call TimerStart( Timer[i], 0.0, false, function Trig_Shield_Timer )
    endif
    N++
    set Trigger[N] = CreateTrigger()
    set Timer[N] = CreateTimer()
    set Iuse[N] = N_DEF
    set CASTER[N] = GetTriggerUnit()
    set DAMAGE[N] = 0.
    set TARGET[N] = GetSpellTargetUnit()
    DMG_REDUC
    call TimerStart ( Timer[N], TIME_OUT, false, function Trig_Shield_Timer )
    if IsUnitAlly(TARGET[N], GetOwningPlayer(CASTER[N])) then
        call TriggerAddCondition( Trigger[N], Condition( function Trig_Shield_Conditions_Ally ) )
    else
        call TriggerAddCondition( Trigger[N], Condition( function Trig_Shield_Conditions_Enemy ) )
    endif
    call TriggerRegisterUnitEvent( Trigger[N], TARGET[N], EVENT_UNIT_DAMAGED )
    call TriggerAddAction( Trigger[N], function Trig_Shield_Actions_Ally )
endfunction

//===========================================================================
private function Trig_Shield_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == SPELL
endfunction
private function InitTrig_Shield takes nothing returns nothing
    set gg_trg_Shield = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Shield, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Shield, Condition( function Trig_Shield_Conditions ) )
    call TriggerAddAction( gg_trg_Shield, function Trig_Shield_Actions )
endfunction

endscope