function IsPointInArea takes real x, real y, integer k returns boolean
return (IsPointInRegion(udg_Region[k], x, y))
endfunction

//Проверка IsPointInRegionVillage помогает определить занято место или нет
//У каждого региона udg_Region[] отдельный земельный участок
//В отличии от обычных областей udg_Region[] в udg_Territory_of_the_Village добавляют все все регионы. Это позволяет просто проверить в будущем занято или нет 
function IsPointInRegionVillage takes real x, real y returns boolean
return (IsPointInRegion(udg_Territory_of_the_Village, x, y))
endfunction

//лежит ли точка на покупаемом участке
//проверяет лишь нахождение точки на свободном участке
function IsPointInArea_1 takes real x, real y returns boolean
return (  (PointInRect1(x,y,udg_rect_minx_p1,udg_rect_maxx_p1,udg_rect_miny_p1,udg_rect_maxy_p1) ) and (not IsPointInRegionVillage(x, y)))
endfunction
//Точка лежит внутри многоугольника
//Проверяет принадлежность точки внутри земельного участка деревни IsPointInArea вместе с покупаемым участком udg_CheckRect 
function IsPointInArea_2 takes real x, real y, integer n returns boolean
return IsPointInArea(x,y,n) or  IsPointInArea_1(x, y)
endfunction
//Лежит ли точка внутри многоугольника и свободна точка от udg_Check_Region
//Это проверка необходима для разбивки многоугольника на ректы (прямоугольники)
//Но сперва необходимо проверить, лежит рект снаружи или внутри. Поэтому проверяем лежит ли центр внутри
//Когда мы находим две вершины ректа, то рект добавляем в временный udg_Check_Region, чтобы этот участок больше не трогали
function IsPointInArea_3 takes real x, real y returns boolean
return (IsPointInArea_2(x,y,udg_temp_integer))and (not IsPointInRegion(udg_Check_Region, x,y) )
endfunction

//CountOccupiedVertexsInRegion - ищет число занятых соседних точек
//Проверка позволяет определять касается ли точка с границей региона или ректа udg_CheckRect (k>0), лежит внутри (k=4) или не лежит (k=0).
//Помогает искать и создавать вершины многоугольника
//Проверяются обычно 4 диагональные клетки или... если быть точным, проверяем 4 точки
function CountOccupiedVertexsInRegion takes real x, real y, integer n returns integer
//Ранее boolean-проверкой IsPointInRegion определял ОДНУ соседнюю клетку, тк расчитывал на меньшее число операции. И если boolean-состояние клетки меняется, значит, упирается в границы. И стоит остановиться циклу.
//Но к сожалению, эта boolean-проверка IsPointInRegion не всегда работает точно. Если добавить рект в регион с помощью нативки RegionAddRect, вы получите совсем другие результаты. 
//-----
//   ПРОБЛЕМА ПЕРВАЯ: Если точнее, регион берет не точками, а ячейками, мин ячейка имеет размер 32x32 (в редакторе можно включить сетку: Вид -> Сетка G -> Мелкая). И вы можете получить совсем другие результаты при проверке IsPointInRegion
//   Если у вас какие-то произвольные координаты вершин ректа, то при добавлении в нативку RegionAddRect координаты подправляют на ближайщие кратные числу 32. Типа -96,-64,-32,0,32,64, 96, 128 итд 
//   Эта нативка RegionAddRect иногда добавляет лишнее, это очень плохо проверка IsPointInRegion. Как говорил, она клеточками занимает область. есть добавить рект с вершинами (minx=0, miny=0,maxx=32.,maxy=32). То рект он добавляет с размерами (minx=0,miny=0,maxx=64.,maxy=64). Короче берет ближайшую координату кратно числу 32. Если взять число 64, то вставит 96. Если 96, то 128. Пробовал меньше 31, подправляет на 32.
//   Нсли занять точку (32,32) то регион занимает ячейку (minx=32-maxx=64, miny=32-maxy=64). Теперь вы должны понимать как это работает. Если добавляю рект с вершинами (minx=0, miny=0,maxx=32.,maxy=32). То рект он добавляет с размерами (minx=0,miny=0,maxx=64.,maxy=64).
//-----
//   ПРОБЛЕМА ВТОРАЯ: Алгоритм. Проблема как раз возникает, если два игрока делят одну ячейку или точнее два граничащих объекта (пример ректы) имеют общую границу.
//   Регион то хранит не в виде точек, а ячеек. Не получится границу линиями, кто-то обязательно отожмет клетку. IsPointInRegion скажет, что клетка занята, поэтому завершит цикл раньше. А на деле оставит лишнюю ячейку, это еще надо будет как-то заранее выверять и мучиться. Придумал два-три алгоритма, не так хорошо работали. Потом еще больше нагромождении в виде доп проверок.
//----
//Поэтому сравнивают сразу несколько соседних клеток, проверяя "лежит ли точка в участке" и выводят те числа, которые приводят  изменению.
//Можно было проверять соседние клетки по вертикали и по горизонтали, но по сравнению с "проверкой соседних клеток по диагонали" это не практично.
//Проверка по диагонали позволяет определять направление, двигаясь по часовой стрелке. а еще заранее исключает точку x,y, образующую одну общую вершину
// 1 point \ | / 2 point |
// ----------?-------------
// 3 point / | \ 4 point |
// ----------| ----------|-


local integer a = 0
local real r = 2.00
local real angle

//1) берем 4 точки от точки x,y
//считаем кол-во лежащих точек
if IsPointInArea_2(x-r,y+r,n) then
    set udg_px[a] = x-r
    set udg_py[a] = y+r
    set a = a + 1
endif
if IsPointInArea_2(x+r,y+r,n) then
    set udg_px[a] = x+r
    set udg_py[a] = y+r
    set a = a + 1
endif
if IsPointInArea_2(x+r,y-r,n) then
    set udg_px[a] = x+r
    set udg_py[a] = y-r
    set a = a + 1
endif
if IsPointInArea_2(x-r,y-r,n) then
    set udg_px[a] = x-r
    set udg_py[a] = y-r
    set a = a + 1
endif

//Проверка не образует ли одну общую вершину (2 ректа могут касаться углами)
//            ¦ ¦ ¦ ¦ ¦ ¦ ¦
//            ¦ ¦ ¦ ¦ ¦ ¦ ¦
//^^^^^^^^^^^?¦ ¦ ¦ ¦ ¦ ¦ ¦
//^^^^^^^^^^^^
//^^^^^^^^^^^^
//Если 2 занятые точки не имеют 90 гр значит это диагонально касаются
if a == 2 then
    set angle = Acos(AngleBetweenTwoVectors(udg_px[0]-x,udg_py[0]-y, udg_px[1]-x,udg_py[1]-y)) * bj_RADTODEG
    //call DisplayDebugTextToPlayer("угол: " + R2S(angle) )
    if angle == 90.00 then
        return 2
    else
        return 5
    endif

endif

return a
endfunction