globals 

real Madness_AoE = 500.
real Madness_Duration = 5.
integer Madness_AbilityCode = 'A000'

hashtable hash   // нам нужен хеш 
endglobals

function Trig_Madness_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == Madness_AbilityCode
endfunction
function MadnessFilter takes nothing returns boolean
    return ( GetOwningPlayer(GetFilterUnit()) == Player(PLAYER_NEUTRAL_AGGRESSIVE) )
endfunction
function MadnessStop takes nothing returns nothing
	call IssueImmediateOrder(GetEnumUnit(),"stop")
endfunction
function MadnessTimer takes nothing returns nothing
	local timer tt=GetExpiredTimer()
	local group gr=LoadGroupHandle(hash,GetHandleId(tt),1)
	call ForGroup(gr, function MadnessStop)
	call DestroyGroup(gr)
	call FlushChildHashtable(hash,GetHandleId(tt))
	call DestroyTimer(tt)
endfunction
function Trig_Madness_Actions takes nothing returns nothing
	local real x=GetSpellTargetX()
	local real y=GetSpellTargetY()
	local group gr=CreateGroup()
	local group gr2 = CreateGroup()
	local unit t
	local unit t2
	local unit last=null
	local timer tt
	call GroupEnumUnitsInRange(gr,x,y, Madness_AoE, Filter(function MadnessFilter))
	loop
		set t=FirstOfGroup(gr)
		exitwhen t==null
		call GroupRemoveUnit(gr,t)
		set t2=FirstOfGroup(gr)
		if t2!=null then
			call IssueTargetOrder(t,"attack",t2)
			call IssueTargetOrder(t2,"attack",t)
			call GroupRemoveUnit(gr,t2)
			call GroupAddUnit(gr2,t)
			call GroupAddUnit(gr2,t2)
		elseif last!=null then
			call IssueTargetOrder(t,"attack",last)
			call GroupAddUnit(gr2,t)
		endif
		set last=t
		
	endloop
	call DestroyGroup(gr)
	if BlzGroupGetSize(gr2) >0 then
		set tt=CreateTimer()
		call SaveGroupHandle(hash,GetHandleId(tt),1,gr2)
		call TimerStart(tt,Madness_Duration,false,function MadnessTimer)
		return
	endif
	call DestroyGroup(gr2)
	
endfunction

//===========================================================================
function InitTrig_Madness takes nothing returns nothing
	set hash=InitHashtable()  // инициализация хеша
    set gg_trg_Madness = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Madness, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Madness, Condition( function Trig_Madness_Conditions ) )
    call TriggerAddAction( gg_trg_Madness, function Trig_Madness_Actions )
endfunction