library Test initializer Init


    globals
    
        private camerasetup array cameras
        
        private effect e
        
        private real ex = .0
        private real ey = .0
        private real ez = 150.
        
        private MATRIX3 rotation 
    
    endglobals
    
    
    private function RotationMatrixToEuler takes MATRIX3 R returns VECTOR3
    
        local real x
        local real y
        local real z
        local real sy = SquareRoot(R.m11 * R.m11  +  R.m21 * R.m21)
     
        local boolean singular = sy < .000001 or sy == 0 // If
     
        if not singular then
        
            set x = Atan2(R.m32 , R.m33)
            set y = Atan2(-R.m31, sy)
            set z = Atan2(R.m21, R.m11)
        
        else
        
            set x = Atan2(-R.m23, R.m22)
            set y = Atan2(-R.m31, sy)
            set z = 0
            
        endif
        
        return VECTOR3.New_1(x, y, z)
    
    endfunction
    
    
    private function UpdateEffectOrientation takes nothing returns nothing
    
        local VECTOR3 euler
    
        local VECTOR3 v1
        local VECTOR3 v2
        local VECTOR3 v3
        
        local VECTOR3 X
        local VECTOR3 Y
        local VECTOR3 Z
        
        local VECTOR3 cX = VECTOR3.New_1(0, 0, 1)
        
        set v1 = VECTOR3.New_1(              /*
            */ GetCameraEyePositionX() - ex, /*
            */ GetCameraEyePositionY() - ey, /*
            */ GetCameraEyePositionZ() - ez)    
            
        set v2 = Vec3Cross(VECTOR3.New_0(), v1, cX)
        set v3 = Vec3Cross(VECTOR3.New_0(), v1, v2)
            
        set X = Vec3Normalize(VECTOR3.New_0(), v1)
        set Z = Vec3Normalize(VECTOR3.New_0(), v2)
        set Y = Vec3Normalize(VECTOR3.New_0(), v3)
        
        set rotation.m11 = X.x
        set rotation.m12 = X.y
        set rotation.m13 = X.z
        
        set rotation.m21 = Y.x
        set rotation.m22 = Y.y
        set rotation.m23 = Y.z
        
        set rotation.m31 = Z.x
        set rotation.m32 = Z.y
        set rotation.m33 = Z.z
        
        set euler = RotationMatrixToEuler(rotation)
        
        call BlzSetSpecialEffectOrientation(e, euler.x, euler.y, euler.z)
    
        call v1.destroy()
        call v2.destroy()
        call v3.destroy()
        
        call cX.destroy()
    
        call X.destroy()
        call Y.destroy()
        call Z.destroy()
        
    endfunction
    
    private function SetCamera takes nothing returns nothing
    
        call CameraSetupApplyForceDuration(cameras[S2I(GetEventPlayerChatString())], false, .5)
        
    endfunction
    
    
    private function Init takes nothing returns nothing
    
        local trigger t = CreateTrigger()    
        
        call TriggerRegisterPlayerChatEvent(t, Player(0), "", false)
        call TriggerAddAction(t, function SetCamera)        
        
        set t = null

        set cameras[1] = gg_cam_Camera_001
        set cameras[2] = gg_cam_Camera_002
        set cameras[3] = gg_cam_Camera_003
        set cameras[4] = gg_cam_Camera_004

        set cameras[5] = gg_cam_Camera_005
        set cameras[6] = gg_cam_Camera_006
        set cameras[7] = gg_cam_Camera_007
        set cameras[8] = gg_cam_Camera_008
        
        set rotation = MATRIX3.New_0()
        
        set e = AddSpecialEffect("units\\human\\Footman\\Footman.mdl", .0, .0)
        call BlzSetSpecialEffectPosition(e, ex, ey, ez)
        
        call TimerStart(CreateTimer(), .03125, true, function UpdateEffectOrientation)

    endfunction
    
    
endlibrary