struct MBSNode
    readonly MinionBuff buf
    readonly integer number
    thistype prev = 0
    thistype next = 0
    
    method basicInit takes MinionBuff buf, integer number returns nothing
        static if ErrorDetectionEnabled_MBSNode then
            if this == 0 then
                call ErrorOccurred("Error: MBSNode struct has run out of indexes. Current amount of indexes is 8190", "MBSNodeError")
            endif
        endif
        set this.buf = buf
        set this.number = number
    endmethod
    
    method removeFromList takes nothing returns nothing
        if prev != 0 then
            set prev.next = next
        endif
        if next != 0 then
            set next.prev = prev
        endif
    endmethod
endstruct

struct MBSNodeReal extends MBSNode
    real value = 0.
endstruct

struct MBSNodeInt extends MBSNode
    integer value = 0
endstruct

struct MBSNodeIntNReal extends MBSNode
    integer value = 0
    real rvalue = 0.
endstruct

// Name - имя типа баффа
// ntyp - тип ячейки
// values - если есть значения у баффа
// bool - если значения типа boolean
// null - нуль для заданного типа значений.

//! textmacro MBSList takes Name, ntyp, values, type, bool, null
    private MBSNode$ntyp$ head$Name$
    readonly integer buffsAmount$Name$ = 0
    
    method add$Name$Buff takes MinionBuff obj returns MBSNode$ntyp$
        local MBSNode$ntyp$ node = MBSNode$ntyp$.create()
        if buffsAmount$Name$ == 0 then
            set head$Name$ = node
        else
            set node.next = head$Name$
            set head$Name$.prev = node
            set head$Name$ = node
        endif
        set BuffCounter = BuffCounter + 1
        set buffsAmount$Name$ = buffsAmount$Name$ + 1
        call node.basicInit(obj, BuffCounter)
        //call DebugMsg("Current amount of $Name$ buffs is " + I2S(buffsAmount$Name$) + ".")
        return node
    endmethod
    
    method remove$Name$Buff takes MBSNode$ntyp$ node returns nothing
        set buffsAmount$Name$ = buffsAmount$Name$ - 1
        if head$Name$ == node then
            set head$Name$ = node.next
        endif
        static if $values$ then
            static if $bool$ then
                set booleanAmount$Name$ = booleanAmount$Name$ - node.value
                set total$Name$Bonus = booleanAmount$Name$ > 0
            else
                set total$Name$Bonus = total$Name$Bonus - node.value
            endif
        endif
        call node.removeFromList()
        call node.destroy()
        //call DebugMsg("Current amount of $Name$ buffs is " + I2S(buffsAmount$Name$) + ".")
    endmethod
    
    static if $values$ then
        static if $bool$ then
            private integer booleanAmount$Name$ = 0
            readonly boolean total$Name$Bonus = false
        else
            readonly $type$ total$Name$Bonus = $null$
        endif
        
        method change$Name$Value takes MBSNode$ntyp$ node, $type$ value returns nothing
        static if $bool$ then
            local integer v = B2I(value)
            set booleanAmount$Name$ = booleanAmount$Name$ - node.value + v
            set total$Name$Bonus = booleanAmount$Name$ > 0
            set node.value = v
        else
            set total$Name$Bonus = total$Name$Bonus - node.value + value
            set node.value = value
        endif
        endmethod
    endif
//! endtextmacro

// Макрос ниже также используется для удаления баффов конкретного типа при каких-то обстоятельствах.
// pos - бафф положительный.
// Ячейки удаляются с удалением баффа.

//! textmacro DeleteBuffs takes Name, first, pos
        static if $first$ then
        local MBSNode node = head$Name$
        local MBSNode temp
        else
        set node = head$Name$
        endif
        loop
            exitwhen node == 0
            set temp = node.next
            $pos$if node.buf.buffdata.negative then
                call node.buf.destroy()
            $pos$endif
            set node = temp
        endloop
//! endtextmacro
...
    method onDestroy takes nothing returns nothing
        //! runtextmacro DeleteBuffs("EoT", "true", "//# ")
        //! runtextmacro DeleteBuffs("Shield", "false", "//# ")
        //! runtextmacro DeleteBuffs("MoveSpeed", "false", "//# ")
        //! runtextmacro DeleteBuffs("Stun", "false", "//# ")
        //! runtextmacro DeleteBuffs("Persistence", "false", "//# ")
        //! runtextmacro DeleteBuffs("PhysArmor", "false", "//# ")
        //! runtextmacro DeleteBuffs("MagcArmor", "false", "//# ")
        //! runtextmacro DeleteBuffs("Armor", "false", "//# ")
        //! runtextmacro DeleteBuffs("PhysImmune", "false", "//# ")
        //! runtextmacro DeleteBuffs("MagcImmune", "false", "//# ")
        //! runtextmacro DeleteBuffs("Protection", "false", "//# ")
        //! runtextmacro DeleteBuffs("Invul", "false", "//# ")
        call DebugMsg("MinionBuffStorage " + I2S(this) + " is deleted.")
    endmethod

struct MinionBuff
    integer typ
    Minion target
    unit source
    CustomPlayer owner
    MinionBuffData buffdata
    integer currticks = 0
    boolean isRunning = false
    MBSNode node1
    MBSNode node2
    MBSNode node3
    
//! runtextmacro CustomTimer("t", "Timer", "MinionBuff", "false")

    method onDestroy takes nothing returns nothing
        call DeleteTimer()
        call RemoveSavedInteger(Hash, target.id, typ)
        call UnitRemoveAbility(target.minion, buffdata.effectid)
        set source = null
        call DebugMsg("MinionBuff " + I2S(this) + " is deleted.")
    endmethod
    
    method basicInit takes Minion host, unit src, CustomPlayer p, integer T returns nothing
        static if ErrorDetectionEnabled_MinionBuff then
            if this == 0 then
                call ErrorOccurred("Error: MinionBuff struct has run out of indexes. Current amount of indexes is 8190", "MinionBuffError")
            endif
        endif
        set typ = T
        set target = host
        set source = src
        set owner = p
        set buffdata = p.minion_buffdata[T]
        call InitTimer()
        call SaveInteger(Hash, target.id, T, this)
        //call DebugMsg("MinionBuff " + I2S(this) + " is created.")
    endmethod

...

endstruct

struct BuffMultishotDoT extends MinionBuff
    method onCreate takes nothing returns nothing
        set node1 = target.addEoTBuff(this)
    endmethod
    
    method onDestroy takes nothing returns nothing
        call target.removeEoTBuff(node1)
    endmethod

    method tickAction takes nothing returns boolean
        local Tower dd
        if UnitExists(source) then
            set dd = GetUnitUserData(source)
            call dd.dealDamage(target, AbilMultishot(dd.abil).dot, AbilMultishot.dottype, false)
            return currticks == 0
        endif
        return true
    endmethod
    
    static method launch takes Minion m, Tower caster returns nothing
        //                     target,     sourceunit,          owner,           name,    neg,  disabl, chkowne, args
        //! runtextmacro InitBuff("m", "caster.tower", "caster.owner", "MultishotDoT", "true", "false", "false", "")
        call startPeriodic(buffdata.startticks)
    endmethod
endstruct

struct BuffMultishotSlow extends MinionBuff
    method onCreate takes real slow returns nothing
        set node1 = target.addMoveSpeedBuff(this, slow)
    endmethod
    
    method onDestroy takes nothing returns nothing
        call target.removeMoveSpeedBuff(node1)
    endmethod
    
    static method launch takes Minion m, Tower caster, real slow returns nothing
        //! runtextmacro InitBuff("m", "caster.tower", "caster.owner", "MultishotSlow", "true", "true", "false", "slow")
        call start()
    endmethod
endstruct