globals
    key TimerParentKey
    constant hashtable Hash = InitHashtable()
endglobals

function DebugMsg takes string s returns nothing
    debug call DisplayTimedTextToPlayer(GetLocalPlayer(), 0., 0., 5., s)
endfunction

function GetCustomTimer takes nothing returns integer
    return LoadInteger(Hash, TimerParentKey, GetHandleId(GetExpiredTimer()))
endfunction

function BindTimerToStruct takes timer t, integer this returns nothing
    call SaveInteger(Hash, TimerParentKey, GetHandleId(t), this)
endfunction

function UnbindTimerFromStruct takes timer t returns nothing
    call PauseTimer(t)
    call RemoveSavedInteger(Hash, TimerParentKey, GetHandleId(t))
    call DestroyTimer(t)
endfunction

//! textmacro CustomTimer takes var, fname, name
    readonly timer $var$

    private method Init$fname$ takes nothing returns nothing
        set $var$ = CreateTimer()
        call BindTimerToStruct($var$, this)
        //call DebugMsg("$fname$ " + I2S(this) + " of $name$ is created.")
    endmethod
        
    private method Delete$fname$ takes nothing returns nothing
        call UnbindTimerFromStruct($var$)
        set $var$ = null
        //call DebugMsg("$fname$ " + I2S(this) + " of $name$ is deleted.")
    endmethod
//! endtextmacro

//! textmacro CustomTimerSafe takes var, fname, name
    readonly timer $var$

    private method Init$fname$ takes nothing returns nothing
        if $var$ == null then
            set $var$ = CreateTimer()
            call BindTimerToStruct($var$, this)
            //call DebugMsg("$fname$ " + I2S(this) + " of $name$ is created.")
        endif
    endmethod
        
    private method Delete$fname$ takes nothing returns nothing
        if $var$ != null then
            call UnbindTimerFromStruct($var$)
            set $var$ = null
            //call DebugMsg("$fname$ " + I2S(this) + " of $name$ is deleted.")
        endif
    endmethod
//! endtextmacro

struct TowerAbility
    static Tower Caster

    TAD data
    Tower caster
    
    static method create takes Tower m, integer T returns thistype
        local thistype this = allocate()
        set data = TAD[T]
        set caster = m
        set m.abil = this
        call UnitAddAbility(m.tower, data.info_id)
        return this
    endmethod
    
    stub method incLevel takes nothing returns nothing
    endmethod
endstruct

struct AbilGoldMining extends TowerAbility
    static constant real period = 1.
    // Defaults
    static constant integer defincome = 1
    // Increments
    static constant integer incincome = 1
    // Additions
    static constant integer b1_income = 1
    static constant integer b2_income = 3
    
    integer income = defincome
    CustomPlayer owner

//! runtextmacro CustomTimer("t", "Timer", "AbilGoldMining")

    method onDestroy takes nothing returns nothing
        call DeleteTimer()
    endmethod
    
    method incLevel takes nothing returns nothing
        set income = income + incincome
        if caster.level == data.b1 then
            set income = income + b1_income
        elseif caster.level == data.b2 then
            set income = income + b2_income
            call caster.removeSelfUpgrade()
        endif
    endmethod
    
    static method addGold takes nothing returns nothing
        local thistype this = GetCustomTimer()
        call owner.addGold(income)
        call owner.createGoldTextUnit(I2S(income), caster.tower)
    endmethod
    
    static method init takes nothing returns nothing
        local Tower m = Caster
        local thistype this = allocate(m, AbilGoldMiningId)
        set owner = m.owner
        call InitTimer()
        call TimerStart(t, period, true, function thistype.addGold)
        call DebugMsg("AbilGoldMining " + I2S(this) + " is created.")
    endmethod
endstruct