struct DMD
        trigger trg
        triggercondition trc
        triggeraction tra
        triggeraction extra
        unit cast
        unit targ
        unit ex
        integer id
        timer trix
        boolean del
            
        method FlushData takes nothing returns nothing
            call DisableTrigger( .trg )
            call TriggerRemoveCondition( .trg, .trc )
            call TriggerRemoveAction( .trg, .tra )
            call TriggerRemoveAction( .trg, .extra )
            call TriggerClearActions( .trg )
            call TriggerClearConditions( .trg )
            call RemoveDataBX( .trg )
            call RemoveDataBX( .trix )
            call DestroyTrigger( .trg )
            call DestroyTimer( .trix )

            set this.trg = null
            set this.trc = null
            set this.tra = null
            set this.extra = null
            set this.cast = null
            set this.targ = null
            set this.ex = null
            set this.trix = null
            set this.id = 0
            set this.del = false
        endmethod
    endstruct

    function IsTargetHasBuff takes nothing returns boolean
        local DMD st = GetDataBX( GetTriggeringTrigger( ) )
        set bj_lastEventId = GetTriggerEventId( )
        
        if bj_lastEventId == EVENT_WIDGET_DEATH then
            call TriggerRemoveAction( st.trg, st.tra )
            return true
        endif
        
        if bj_lastEventId == EVENT_UNIT_DAMAGED then
            if  GetEventDamageSource( ) == DummyAttacker then
                return false
            elseif GetEventDamage( ) == 0.00 and GetEventDamageSource( ) == st.cast  and GetUnitAbilityLevel( st.targ, 'BNss' ) > 0  then
                call TriggerRemoveAction( st.trg, st.tra )
                return true
            endif
        endif
    
        return GetEventDamage( ) == 0.00 and GetUnitAbilityLevel( st.targ, st.id ) > 0 and GetEventDamageSource( ) == st.cast 
    endfunction

    function Destroy_DMD takes nothing returns nothing
        local DMD st = GetDataBX( GetExpiredTimer( ) )
        call st.FlushData( )
        call st.destroy( )
    endfunction
    
    function RemoveDMDBuff takes nothing returns nothing
        local DMD st = GetDataBX( GetTriggeringTrigger( ) )
        if st.del then
            call UnitRemoveAbility( st.targ, st.id )
        endif
        call PauseTimer( st.trix )
        call DisableTrigger( st.trg )
        call TimerStart( st.trix, 10.00, false, function Destroy_DMD )
        return
    endfunction
    
    function DummyMissile takes unit target, unit caster, integer buffid, real time, boolean del, code actions returns nothing
        local DMD st = DMD.create( )
        set st.cast = caster
        set st.targ = target
        set st.id = buffid
        set st.del = del
        set st.trix = CreateTimer( )
        set st.trg = CreateTrigger( )
        set st.trc = TriggerAddCondition( st.trg, Condition( function IsTargetHasBuff ) )
        set st.tra = TriggerAddAction( st.trg, actions )
        set st.extra = TriggerAddAction( st.trg, function RemoveDMDBuff )
        call TriggerRegisterUnitEvent( st.trg, target, EVENT_UNIT_DAMAGED )
        //call TriggerRegisterUnitEvent( st.trg, target, EVENT_UNIT_SPELL_EFFECT)
        call TriggerRegisterDeathEvent( st.trg, target )
        call TimerStart( st.trix, time, false, function Destroy_DMD )
        call SetDataBX( st.trg, st )
        call SetDataBX( st.trix, st )
    endfunction
    

library IsUnitInvulnerableCheck initializer Init

globals
    unit DummyAttacker
    trigger gg_trg_Damage_Blocker
    group gg_grp_CheckedGroup
    hashtable GameData = InitHashtable( )
    boolean IsInvul = false
endglobals

function Trig_Damage_Blocker_Conditions takes nothing returns boolean
    return GetEventDamage() > 0.00 and GetEventDamageSource( ) == DummyAttacker
endfunction

function Timer_Heal_Unit_Expires takes nothing returns nothing
    local timer t = GetExpiredTimer( )
    local integer id = GetHandleId(t)
    local unit Damaged = LoadUnitHandle( GameData, id, 0 )
    
    call UnitRemoveAbility( Damaged, 'AMHP' )
    call SetUnitState( Damaged, UNIT_STATE_LIFE, LoadReal( GameData, id, 1 ) )
    call SetUnitState( Damaged, UNIT_STATE_MANA, LoadReal( GameData, id, 2 ) )
   
    call DestroyTimer(t)
    call FlushChildHashtable( GameData, id )
    
    set Damaged = null
    set t = null
endfunction 

function Trig_Damage_Blocker_Actions takes nothing returns nothing
    local unit Damaged = GetTriggerUnit( )
    local timer t = CreateTimer()
    local integer id = GetHandleId( t )

    call SaveUnitHandle( GameData, id, 0, Damaged )
    call SaveReal( GameData, id, 1, GetUnitState( Damaged, UNIT_STATE_LIFE ) )
    call SaveReal( GameData, id, 2, GetUnitState( Damaged, UNIT_STATE_MANA ) )
    
    call TimerStart( t, 0.00, false, function Timer_Heal_Unit_Expires )
    
    call UnitAddAbility( Damaged, 'AMHP' )
    call SetUnitState( Damaged, UNIT_STATE_LIFE, GetUnitState( Damaged, UNIT_STATE_MAX_LIFE ) )
    
    set IsInvul = true
    
    set Damaged = null
    set t = null
endfunction


function IsUnitInvul takes unit enemy returns boolean
    local real hp = GetUnitState( enemy, UNIT_STATE_LIFE )
    local real mp = GetUnitState( enemy, UNIT_STATE_MANA )
    
	set IsInvul = false

    if hp < 0.405 or GetUnitTypeId(enemy) < 1 then
        return true
    elseif GetUnitAbilityLevel( enemy, 'Avul' ) > 0 then
        return true
    endif
        
    if not IsUnitInGroup( enemy, gg_grp_CheckedGroup ) then
        call TriggerRegisterUnitEvent( gg_trg_Damage_Blocker, enemy, EVENT_UNIT_DAMAGED )
        call GroupAddUnit( gg_grp_CheckedGroup, enemy )
    endif

    call EnableTrigger( gg_trg_Damage_Blocker )
    call UnitDamageTarget( DummyAttacker, enemy, 100.00, false, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_UNKNOWN, WEAPON_TYPE_WHOKNOWS )
    call DisableTrigger( gg_trg_Damage_Blocker )
    
    return IsInvul
endfunction 

private function Init takes nothing returns nothing
    set DummyAttacker = CreateUnit( Player(12), 'hpea', 0.00,0.00, 270.00 )
    
    call SetUnitPathing( DummyAttacker, true )
    call PauseUnit( DummyAttacker, true )
    call SetUnitInvulnerable( DummyAttacker, true )
    call ShowUnit( DummyAttacker, false )
    
    
    set gg_grp_CheckedGroup = CreateGroup( )
    set gg_trg_Damage_Blocker = CreateTrigger( )

    call TriggerAddCondition( gg_trg_Damage_Blocker, Condition( function Trig_Damage_Blocker_Conditions ) )
    call TriggerAddAction( gg_trg_Damage_Blocker, function Trig_Damage_Blocker_Actions )
    call DisableTrigger( gg_trg_Damage_Blocker )
endfunction

endlibrary