library CyclopsRoar
globals
    constant hashtable H = InitHashtable( )
    private constant real TimerPeriodic = 0.10  // периодичность сбития приказа
    private constant real DistancePoint = 50.00 // точка (дистанция), куда отбегать в зависимости от угла между кастером и таргетом
endglobals

private struct RoarS
    unit caster
    unit target
    real time
endstruct

native UnitAlive takes unit id returns boolean

private function Move takes nothing returns nothing
    local timer t = GetExpiredTimer( )
    local RoarS A = LoadInteger( H, GetHandleId( t ), 0 )
    local real x = GetUnitX( A.target )
    local real y = GetUnitY( A.target )
    local real a = Atan2( y - GetUnitY( A.caster ), x - GetUnitX( A.caster ) )
    
    call IssuePointOrder( A.target, "smart", x + DistancePoint * Cos( a ), y + DistancePoint * Sin( a ) )
    
    set A.time = A.time - TimerPeriodic
    if A.time <= 0.00 or not UnitAlive( A.caster ) or not UnitAlive( A.target ) then
        call FlushChildHashtable( H, GetHandleId( t ) )
        call DestroyTimer( t )
        
        set udg_TempUnit = A.target
        call TriggerExecute( gg_trg_SpellEnd )
        
        set A.caster = null
        set A.target = null
        call A.destroy( )
    else
        call TimerStart( t, TimerPeriodic, false, function Move )
    endif
    
    set t = null
endfunction

function Spell_Actions takes unit caster, unit target, real time returns nothing
    local timer t = CreateTimer( )
    local RoarS A = RoarS.create( )
    
    set A.caster = caster
    set A.target = target
    set A.time   = time
    
    call SaveInteger( H, GetHandleId( t ), 0, A )
    call TimerStart( t, 0.00, false, function Move )
    
    set t = null
endfunction

//===========================================================================
function InitTrig_Spell takes nothing returns nothing
    //set gg_trg_Spell = CreateTrigger(  )
endfunction
endlibrary

library CyclopsSlam
globals
    constant hashtable H = InitHashtable( )
    private constant group TempG = CreateGroup( )
    
    private constant real MaxDistance = 600.00 // макс дистанция отбрасывания
    private constant real MinDistance = 0.00   // мин дистанция отбрасывания ( без понятия зачем, мб пригодится )
    private constant real DiscardingS = 15.00  // скорость полёта отброшенных
    private constant real TimerPeriodic = 0.01 // периодичность полёта таймера для отброшенных противников ( чем выше - тем оптимизированнее и хуже плавность )
    private constant boolean OrderPause = true // сбивать приказы при отбрасывании? true - да, false - нет
    private constant boolean DiscrPause = true // прекращать отталкивание если юнит столкнулся с ландом?
    private attacktype AttackType = null
    private damagetype DamageType = null
    private real TempX
    private real TempY
    private real TempReal
    private unit TempUnit
    private item TempItem
endglobals

private function ParabolaZ takes real h, real d, real x returns real
    return (4 * h / d) * (d - x) * (x / d)
endfunction

private struct mys
    unit caster
    real damage
    real radius
    real time
    real timeM
    real height
    attacktype AttackType
    damagetype DamageType
endstruct

private struct MoveS
    unit target
    unit caster
    real speedx
    real speedy
    real distance
    real angle
endstruct

private function Discarding takes nothing returns nothing
    local MoveS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local real x  = GetUnitX( A.target ) + DiscardingS * A.speedx
    local real y  = GetUnitY( A.target ) + DiscardingS * A.speedy
    local boolean b = false
    
    call SetItemPosition( TempItem, x, y )
    call SetItemVisible( TempItem, false )
    if SquareRoot( ( GetItemX( TempItem ) - x ) * ( GetItemX( TempItem ) - x ) + ( GetItemY( TempItem ) - y ) * ( GetItemY( TempItem ) - y ) ) <= 10 then
        call SetUnitX( A.target, x )
        call SetUnitY( A.target, y )
    elseif DiscrPause then
        set b = true
    endif
    
    if OrderPause then
        call IssueImmediateOrder( A.target, "stop" )
    endif
    
    set A.distance = A.distance - DiscardingS
    
    if A.distance <= 0.00 or GetUnitTypeId( A.target ) == 0 or b then
        call SetUnitPathing( A.target, true )
        call FlushChildHashtable( H, GetHandleId( GetExpiredTimer( ) ) )
        call PauseTimer( GetExpiredTimer( ) )
        call DestroyTimer( GetExpiredTimer( ) )
        
        set udg_TempUnit   = A.target
        set udg_LastCaster = A.caster
        call TriggerExecute( gg_trg_DiscardingEnd )
        
        set A.target = null
        set A.caster = null
        call A.destroy( )
    endif
endfunction

private function Damage takes nothing returns nothing
    local timer t = CreateTimer( )
    local MoveS A = MoveS.create( )
    local real x
    local real y
    
    set A.caster = udg_LastCaster
    set A.target = GetEnumUnit( )
    set x = GetUnitX( A.target )
    set y = GetUnitY( A.target )

    set A.speedx = x - TempX
    set A.speedy = y - TempY
    
    set A.distance = SquareRoot( A.speedx * A.speedx + A.speedy * A.speedy )
    set A.speedx = A.speedx / A.distance
    set A.speedy = A.speedy / A.distance
    
    set A.distance = SquareRoot( ( TempX - x ) * ( TempX - x ) + ( TempY - y ) * ( TempY - y ) )

    set A.distance = MaxDistance * ( 1 - ( A.distance / MaxDistance ) )
    if A.distance < MinDistance then
        set A.distance = MinDistance
    elseif A.distance > MaxDistance then
        set A.distance = MaxDistance
    endif
    
    call SetUnitPathing( A.target, false )
    call SaveInteger( H, GetHandleId( t ), 0, A )
    call TimerStart( t, TimerPeriodic, true, function Discarding )
    
    call GroupAddUnit( udg_TempGroup, A.target )
    call UnitDamageTarget( udg_LastCaster, A.target, TempReal, false, false, AttackType, DamageType, null )
    set t = null
endfunction

private function Move takes nothing returns nothing
    local mys A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    
    set A.time = A.time - 0.01
    call SetUnitFlyHeight( A.caster, ParabolaZ( A.height, A.timeM, A.time ), 0.00 )
    
    if A.time <= 0. then
        call SetUnitFlyHeight( A.caster, 0.00, 0.00 )
        
        set udg_LastCaster = A.caster
        set TempReal       = A.damage
        set AttackType     = A.AttackType
        set DamageType     = A.DamageType
        set TempX          = GetUnitX( A.caster )
        set TempY          = GetUnitY( A.caster )
        call GroupEnumUnitsInRange( TempG, TempX, TempY, A.radius, udg_DamageCond )
        call ForGroup( TempG, function Damage )
        call GroupClear( TempG )
        
        call FlushChildHashtable( H, GetHandleId( GetExpiredTimer( ) ) )
        call DestroyTimer( GetExpiredTimer( ) )
        
        set A.caster = null
        call A.destroy( )
        
        call TriggerExecute( gg_trg_SpellEnd )
    endif
endfunction

function Spell_Actions takes unit caster, real damage, real time, real height, real radius, attacktype at, damagetype dt returns nothing
    local timer t = CreateTimer( )
    local mys A   = mys.create( )
    
    set A.caster = caster
    set A.damage = damage
    set A.time   = time
    set A.timeM  = time
    set A.height = height
    set A.radius = radius
    set A.AttackType = at
    set A.DamageType = dt
    
    call UnitAddAbility( A.caster, 'Arav' )
    call UnitRemoveAbility( A.caster, 'Arav' )
    call SaveInteger( H, GetHandleId( t ), 0, A )
    call TimerStart( t, 0.01, true, function Move )
    
    set t = null
endfunction

//===========================================================================
function InitTrig_Spell takes nothing returns nothing
    //set gg_trg_Spell = CreateTrigger(  )
    set TempItem = CreateItem( 'spsh', 0, 0 )
    call SetItemVisible( TempItem, false )
endfunction
endlibrary