library SpellLib
globals
    constant hashtable H = InitHashtable( )
    private constant integer SpellID = 'A000' // спелл прыжка
    private constant integer SpellCD = 'A000' // спелл которому сбросить кд
endglobals

private struct SpellS
    unit caster
    unit target
    real speed
    real damage
    real range
    attacktype AttackType
    damagetype DamageType
endstruct

native UnitAlive takes unit id returns boolean

// само движение
private function Move takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local real x   = GetUnitX( A.caster )
    local real y   = GetUnitY( A.caster )
    local real x1  = GetUnitX( A.target )
    local real y1  = GetUnitY( A.target )
    local real d   = SquareRoot( ( x - x1 ) * ( x - x1 ) + ( y - y1 ) * ( y - y1 ) )
    local integer i
    
    set x = x + A.speed * ( ( x1 - x ) / d )
    set y = y + A.speed * ( ( y1 - y ) / d )
    
    call SetUnitX( A.caster, x )
    call SetUnitY( A.caster, y )
    call IssueImmediateOrder( A.caster, "stop" )
    
    if SquareRoot( ( x - x1 ) * ( x - x1 ) + ( y - y1 ) * ( y - y1 ) ) <= A.range + A.speed or GetUnitTypeId( A.target ) == 0 or not UnitAlive( A.caster ) then
        if UnitAlive( A.caster ) and GetRandomInt( 0, 100 ) <= 15 then // восстановить хп юниту с 15% шансом
            call SetWidgetLife( A.caster, GetWidgetLife( A.caster ) + GetUnitState( A.caster, UNIT_STATE_MAX_LIFE ) * 0.15 )
            call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Spells\\Undead\\VampiricAura\\VampiricAuraTarget.mdl", A.caster, "origin" ) )
        endif
        
        if GetRandomInt( 0, 100 ) <= 15 then // ресетнуть абилку с 15% шансом
            set i = GetUnitAbilityLevel( A.caster, SpellCD )
            call UnitRemoveAbility( A.caster, SpellCD )
            call UnitAddAbility( A.caster, SpellCD )
            call SetUnitAbilityLevel( A.caster, SpellCD, i )
        endif
        
        call UnitDamageTarget( A.caster, A.target, A.damage, false, false, A.AttackType, A.DamageType, null )
        call DestroyEffect( AddSpecialEffect( "Objects\\Spawnmodels\\Human\\HumanLargeDeathExplode\\HumanLargeDeathExplode.mdl", x1, y1 ) )
        
        call SetUnitPathing( A.caster, true )
        call FlushChildHashtable( H, GetHandleId( GetExpiredTimer( ) ) )
        call PauseTimer( GetExpiredTimer( ) )
        call DestroyTimer( GetExpiredTimer( ) )
        set A.caster = null
        set A.target = null
        call A.destroy( )
    endif
endfunction

private function SetAnim takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    
    // выставление анимок кастеру
    call SetUnitAnimation( A.caster, "attack slam" )
    call QueueUnitAnimation( A.caster, "stand" )

    call TimerStart( GetExpiredTimer( ), 0.01, true, function Move ) // периодичность полёта
endfunction

function Spell_Actions takes nothing returns boolean
    local timer t
    local SpellS A
    
    if GetSpellAbilityId( ) == SpellID then
        set t = CreateTimer( )
        set A = SpellS.create( )
        
        set A.caster = GetTriggerUnit( )     // тот, кто полетит
        set A.target = GetSpellTargetUnit( ) // тот, в кого полетят
        set A.range  = 100.00 // дистанция столкновения
        set A.speed  = ( SquareRoot( ( GetUnitX( A.caster ) - GetUnitX( A.target ) ) * ( GetUnitX( A.caster ) - GetUnitX( A.target ) ) + ( GetUnitY( A.caster ) - GetUnitY( A.target ) ) * ( GetUnitY( A.caster ) - GetUnitY( A.target ) ) ) - A.range ) * 0.015 // скорость
        set A.damage = GetHeroAgi( A.caster, true ) * ( 2.25 * GetUnitAbilityLevel( A.caster, SpellID ) ) // урон
        set A.AttackType = ATTACK_TYPE_NORMAL // тип атаки
        set A.DamageType = DAMAGE_TYPE_NORMAL // тип урона
        
        call SetUnitPathing( A.caster, false )
        call SaveInteger( H, GetHandleId( t ), 0, A )
        call TimerStart( t, 0.00, false, function SetAnim )
        
        set t = null
    endif
    
    return false
endfunction

//===========================================================================
function InitTrig_Spell takes nothing returns nothing
    local integer index = 0
    set gg_trg_Spell    = CreateTrigger(  )
    
    loop
        call TriggerRegisterPlayerUnitEvent( gg_trg_Spell, Player( index ), EVENT_PLAYER_UNIT_SPELL_EFFECT, null )
        set index = index + 1
        exitwhen index >= 16
    endloop
    call TriggerAddCondition( gg_trg_Spell, Condition( function Spell_Actions ) )
endfunction

endlibrary

library SpellLib
globals
    constant hashtable H           = InitHashtable( )
    private constant group TempG   = CreateGroup( )
    private constant group TempG_1 = CreateGroup( )
    private attacktype AttackType  = null
    private damagetype DamageType  = null
    private boolexpr TempBoolexpr  = null
    private real TempReal
endglobals

private struct SpellS
    unit caster
    real damage
    real radius
    real damagePeriodic
    real time
    group g
    attacktype AttackType
    damagetype DamageType
    boolexpr b
endstruct

private function Damage_2 takes nothing returns nothing
    set udg_TempUnit = GetEnumUnit( )
    if not IsUnitInGroup( udg_TempUnit, TempG_1 ) then
        call GroupAddUnit( TempG_1, udg_TempUnit )
        call UnitDamageTarget( udg_LastCaster, udg_TempUnit, TempReal, false, false, AttackType, DamageType, null )
        call TriggerExecute( gg_trg_OnDamage )
    endif
endfunction

private function Damage_1 takes nothing returns nothing
    call GroupEnumUnitsInRange( TempG, GetUnitX( GetEnumUnit( ) ), GetUnitY( GetEnumUnit( ) ), TempReal, TempBoolexpr )
    call ForGroup( TempG, function Damage_2 )
    call GroupClear( TempG )
endfunction

private function Damage takes nothing returns nothing
    local timer t  = GetExpiredTimer( )
    local SpellS A = LoadInteger( H, GetHandleId( t ), 0 )
    local unit u
    
    set A.time = A.time - A.damagePeriodic
    
    set AttackType     = A.AttackType
    set DamageType     = A.DamageType
    set TempBoolexpr   = A.b
    set udg_LastCaster = A.caster
    set TempReal       = A.radius
    call ForGroup( A.g, function Damage_1 )
    call GroupClear( TempG_1 )
    
    if A.time <= 0.00 then
        call FlushChildHashtable( H, GetHandleId( t ) )
        call DestroyTimer( t )
        
        loop
            set u = FirstOfGroup( A.g )
            exitwhen u == null
            call KillUnit( u )
            call GroupRemoveUnit( A.g, u )
        endloop
        
        call DestroyGroup( A.g )
        set A.g      = null
        set A.caster = null
        call A.destroy( )
    else
        call TimerStart( t, A.damagePeriodic, false, function Damage )
    endif
    
    set t = null
endfunction

function Spell_Actions takes unit caster, integer id, attacktype at, damagetype dt, real damage, real x, real y, real weight, real radius, real distance, real damagePeriodic, real time, boolexpr blxpr returns nothing
    local timer t   = CreateTimer( )
    local SpellS A  = SpellS.create( )
    local boolean b = true
    local real d    = distance / 2
    local real a    = Atan2( y - GetUnitY( caster ), x - GetUnitX( caster ) )
    local real xl   = Cos( a + ( 90 * bj_DEGTORAD ) )
    local real yl   = Sin( a + ( 90 * bj_DEGTORAD ) )
    local unit u
    
    set A.damage = damage
    set A.caster = caster
    set A.radius = radius
    set A.time   = time
    set A.b      = blxpr
    set A.AttackType     = at
    set A.DamageType     = dt
    set A.damagePeriodic = damagePeriodic
    
    set A.g    = CreateGroup( )
    set weight = weight / 2
    set bj_groupEnumOwningPlayer = GetOwningPlayer( A.caster )
    loop
        if b then
            set u = CreateUnit( bj_groupEnumOwningPlayer, id, x + d * xl, y + d * yl, 0.00 )
            set b = false
        else
            set u = CreateUnit( bj_groupEnumOwningPlayer, id, x - d * xl, y - d * yl, 0.00 )
            set b = true
            set d = d + distance
        endif
        call GroupAddUnit( A.g, u )
        exitwhen d >= weight
    endloop
    
    call SaveInteger( H, GetHandleId( t ), 0, A )
    call TimerStart( t, 0.00, false, function Damage )
    
    set u = null
    set t = null
endfunction

//===========================================================================
function InitTrig_Spell takes nothing returns nothing
    //set gg_trg_Spell = CreateTrigger(  )
endfunction
endlibrary