Как сделать MUI через глобалки? - [Jass]

globals
    constant timer TempTimer = CreateTimer( )
    constant group TempGroup = CreateGroup( )
    
    integer max = 0
    
    unit array caster
    unit array dummy
    
    player array owningPlayer
    group array g
    
    real array x
    real array y
    real array angleX
    real array angleY
    real array radius
    real array speed
    real array distance
endglobals

native UnitAlive takes unit id returns boolean

function Move takes nothing returns nothing
    local integer i = 1
    local unit u
    
    loop
        exitwhen i > max
        
        if speed[i] > distance[i] then
            set speed[i] = distance[i]
        endif
        
        set x[i] = x[i] + speed[i] * angleX[i]
        set y[i] = y[i] + speed[i] * angleY[i]
        
        call SetUnitX( dummy[i], x[i] )
        call SetUnitY( dummy[i], y[i] )
        call DestroyEffect( AddSpecialEffect( "Objects\\Spawnmodels\\Other\\NeutralBuildingExplosion\\NeutralBuildingExplosion.mdl", x[i], y[i] ) )
        
        call GroupEnumUnitsInRange( TempGroup, x[i], y[i], radius[i] + 200.00, null )
        
        loop
            set u = FirstOfGroup( TempGroup )
            exitwhen u == null
            call GroupRemoveUnit( TempGroup, u )
            
            if IsUnitInRangeXY( u, x[i], y[i], radius[i] ) then
                if not IsUnitInGroup( u, g[i] ) then
                    if UnitAlive( u ) and IsUnitEnemy( u, owningPlayer[i] ) then
                        call GroupAddUnit( g[i], u )
                        call UnitDamageTarget( caster[i], u, 100.00, false, false, null, null, null )
                    endif
                endif
            endif
        endloop
        
        set distance[i] = distance[i] - speed[i]
        
        if distance[i] <= 0.00 then
            call KillUnit( dummy[i] )
            
            call DestroyGroup( g[i] )
            
            set caster[i] = caster[max]
            set dummy[i] = dummy[max]
            set owningPlayer[i] = owningPlayer[max]
            set g[i] = g[max]
            set x[i] = x[max]
            set y[i] = y[max]
            set angleX[i] = angleX[max]
            set angleY[i] = angleY[max]
            set radius[i] = radius[max]
            set speed[i] = speed[max]
            set distance[i] = distance[max]
            
            set max = max - 1
            set i = i - 1
            
            if max <= 0 then
                call PauseTimer( TempTimer )
            endif
        endif
        
        set i = i + 1
    endloop
endfunction

function Trig_Untitled_Trigger_001_Actions takes nothing returns nothing
    local real a
    
    if max == 0 then
        call TimerStart( TempTimer, 0.03125, true, function Move )
    endif
    
    set max = max + 1
    
    set caster[max] = GetTriggerUnit( )
    set owningPlayer[max] = GetOwningPlayer( caster[max] )
    
    set g[max] = CreateGroup( )
    
    set x[max] = GetUnitX( caster[max] )
    set y[max] = GetUnitY( caster[max] )
    
    set a = Atan2( GetSpellTargetY( ) - y[max], GetSpellTargetX( ) - x[max] )
    
    set angleX[max] = Cos( a )
    set angleY[max] = Sin( a )
    
    set dummy[max] = CreateUnit( owningPlayer[max], 'h000', x[max], y[max], a * bj_RADTODEG )
    
    set radius[max] = 200.00
    set speed[max] = 1000.00 * 0.03125
    set distance[max] = 1000.00
endfunction

//===========================================================================
function InitTrig_Untitled_Trigger_001 takes nothing returns nothing
    set gg_trg_Untitled_Trigger_001 = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Untitled_Trigger_001, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddAction( gg_trg_Untitled_Trigger_001, function Trig_Untitled_Trigger_001_Actions )
endfunction