library AllGlobalsLib
globals
    constant hashtable H = InitHashtable( )
    constant location LFZ = Location( 0.00, 0.00 )
    
    private real MaxX
    private real MinX
    private real MaxY
    private real MinY
endglobals

native UnitAlive takes unit id returns boolean

function GetCorX takes real x returns real
    if x > MaxX then
        return MaxX
    elseif x < MinX then
        return MinX
    endif
    
    return x
endfunction

function GetCorY takes real y returns real
    if y > MaxY then
        return MaxY
    elseif y < MinY then
        return MinY
    endif
    
    return y
endfunction

function GetLocZ takes real x, real y returns real
    call MoveLocation( LFZ, x, y )
    return GetLocationZ( LFZ )
endfunction

struct vector
    real x
    real y
    real z
    
    method length takes nothing returns real
        return SquareRoot( x * x + y * y + z * z )
    endmethod
    
    method normalize takes nothing returns nothing
        local real l = length( )
        
        if l == 0.00 then
            set l = 1.00
        endif
        
        set x = x / l
        set y = y / l
        set z = z / l
    endmethod
    
    static method create takes real x, real y, real z returns thistype
        local thistype this = thistype.allocate( )
        
        set this.x = x
        set this.y = y
        set this.z = z
        
        return this
    endmethod
endstruct

//===========================================================================
function InitTrig_AllGlobals takes nothing returns nothing
    //set gg_trg_AllGlobals = CreateTrigger(  )
    local rect r = GetWorldBounds( )
    
    set MaxX = GetRectMaxX( r )
    set MinX = GetRectMinX( r )
    set MaxY = GetRectMaxY( r )
    set MinY = GetRectMinY( r )
    
    call RemoveRect( r )
    set r = null
endfunction
endlibrary

library SpellLib
globals
    private constant group TempGroup = CreateGroup( )
    private constant group TempGroup1 = CreateGroup( )
    private unit TempUnit = null
endglobals

struct SpellS
    timer t
    player p
    
    unit caster
    unit target
    unit eye
    unit field
    unit laser
    unit laserBig
    
    vector l
    vector array v[4]
    
    integer lvl
    
    real radius
    real radiusEnd
    
    real damage
    real damagePeriodic
    
    real distance
    
    real time
    real timeMax
    
    attacktype attackType
    damagetype damageType
    weapontype weaponType
endstruct

private function Rotation takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local real ax
    local real ay
    local real d
    local unit u
    
    if GetUnitCurrentOrder( A.caster ) == OrderId( "channel" ) then
        set A.time = A.time + 0.01
        set A.timeMax = A.timeMax + 0.01
        
        call SetUnitFacing( A.caster, Atan2( GetUnitY( A.target ) - A.l.y, GetUnitX( A.target ) - A.l.x ) * bj_RADTODEG )
        
        set d = GetUnitFacing( A.caster )
        
        set ax = Cos( d * bj_DEGTORAD )
        set ay = Sin( d * bj_DEGTORAD )
        
        call SetUnitX( A.eye, A.l.x + 275.00 * ax )
        call SetUnitY( A.eye, A.l.y + 275.00 * ay )
        
        call SetUnitX( A.field, A.l.x + 125.00 * ax )
        call SetUnitY( A.field, A.l.y + 125.00 * ay )
        
        call SetUnitFacing( A.eye, d )
        call SetUnitFacing( A.laser, d )
        call SetUnitFacing( A.laserBig, d )
        
        if A.time == 1.15 then
            set A.laser = CreateUnit( A.p, 'u005', A.l.x + 100.00 * ax, A.l.y + 100.00 * ay, d )
            call SetUnitX( A.laser, A.l.x + 100.00 * ax )
            call SetUnitY( A.laser, A.l.y + 100.00 * ay )
            call SetUnitFlyHeight( A.laser, 80.00, 0.00 )
            call UnitApplyTimedLife( A.laser, 'BTLF', 3.00 )
        endif
        
        if A.time >= 1.50 then
            set A.time = 0.00
            
            call SetUnitAnimation( A.field, "birth" )
            call QueueUnitAnimation( A.field, "stand" )
            
            set A.laser = CreateUnit( A.p, 'u007', A.l.x, A.l.y, d )
            call SetUnitFlyHeight( A.laser, 80.00, 0.00 )
            call SetUnitAnimation( A.laser, "death" )
            call UnitApplyTimedLife( A.laser, 'BTLF', 5.00 )
            
            set A.laser = CreateUnit( A.p, 'u001', A.l.x + 125.00 * ax, A.l.y + 125.00 * ay, d )
            call SetUnitX( A.laser, A.l.x + 125.00 * ax )
            call SetUnitY( A.laser, A.l.y + 125.00 * ay )
            call SetUnitFlyHeight( A.laser, 80.00, 0.00 )
            call UnitApplyTimedLife( A.laser, 'BTLF', 3.00 )
        endif
        
        if A.timeMax >= A.damagePeriodic then
            set A.timeMax = 0.00
            
            set d = 0.00
            
            loop
                call GroupEnumUnitsInRange( TempGroup, A.l.x + d * ax, A.l.y + d * ay, A.radius - ( A.radius - A.radiusEnd ) * ( d / A.distance ) + 200.00, null )
                
                loop
                    set u = FirstOfGroup( TempGroup )
                    exitwhen u == null
                    call GroupRemoveUnit( TempGroup, u )
                    
                    if not IsUnitInGroup( u, TempGroup1 ) then
                        if UnitAlive( u ) and IsUnitEnemy( u, A.p ) then // условия для нанесения урона
                            if IsUnitInRangeXY( u, A.l.x + d * ax, A.l.y + d * ay, A.radius - ( A.radius - A.radiusEnd ) * ( d / A.distance ) ) then
                                call SetUnitAbilityLevel( TempUnit, 'A001', A.lvl )
                                call IssueTargetOrder( TempUnit, "slow", u )
                                
                                call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Spells\\Undead\\CarrionSwarm\\CarrionSwarmDamage.mdl", u, "origin" ) )
                                call UnitDamageTarget( A.caster, u, A.damage, false, false, A.attackType, A.damageType, A.weaponType )
                                call GroupAddUnit( TempGroup1, u )
                            endif
                        endif
                    endif
                endloop
                
                if d + 32.00 > A.distance then
                    set d = A.distance
                else
                    set d = d + 32.00
                endif
                
                exitwhen d >= A.distance
            endloop
            
            call GroupClear( TempGroup1 )
        endif
    else
        call PauseTimer( A.t )
        call FlushChildHashtable( H, GetHandleId( A.t ) )
        call DestroyTimer( A.t )
        
        call SetUnitAnimation( A.eye, "death" )
        call UnitApplyTimedLife( A.eye, 'BTLF', 3.00 )
        
        call SetUnitAnimation( A.field, "death" )
        call UnitApplyTimedLife( A.field, 'BTLF', 5.00 )
        
        call SetUnitAnimation( A.laserBig, "death" )
        call UnitApplyTimedLife( A.laserBig, 'BTLF', 6.00 )
        
        set A.t = null
        set A.eye = null
        set A.field = null
        set A.laser = null
        set A.laserBig = null
        set A.caster = null
        set A.target = null
        call A.l.destroy( )
        call A.destroy( )
    endif
endfunction

private function CreateEye takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local SpellS B = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 1 )
    local integer k = 0
    local integer i
    local real array x
    local real array y
    local real array z
    local real array x1
    local real array y1
    local real array z1
    local unit u
    
    set A.time = A.time + 0.01 / A.timeMax
    
    if A.time > 1.00 then
        set A.time = 1.00
    endif
    
    loop
        set x[k] = A.v[k].x
        set y[k] = A.v[k].y
        set z[k] = A.v[k].z
        set x1[k] = B.v[k].x
        set y1[k] = B.v[k].y
        set z1[k] = B.v[k].z
        
        set k = k + 1
        exitwhen k >= 4
    endloop
    
    set k = 0
    
    loop
        set i = 0
        
        loop
            set x[i] = ( 1.00 - A.time ) * x[i] + A.time * x[i + 1]
            set y[i] = ( 1.00 - A.time ) * y[i] + A.time * y[i + 1]
            set z[i] = ( 1.00 - A.time ) * z[i] + A.time * z[i + 1]
            set x1[i] = ( 1.00 - A.time ) * x1[i] + A.time * x1[i + 1]
            set y1[i] = ( 1.00 - A.time ) * y1[i] + A.time * y1[i + 1]
            set z1[i] = ( 1.00 - A.time ) * z1[i] + A.time * z1[i + 1]
            
            set i = i + 1
            exitwhen i > 4 - k
        endloop
        
        set k = k + 1
        exitwhen k >= 4 - 1
    endloop
    
    set x[0] = GetCorX( x[0] )
    set y[0] = GetCorY( y[0] )
    
    call SetUnitX( A.eye, x[0] )
    call SetUnitY( A.eye, y[0] )
    call SetUnitFlyHeight( A.eye, z[0] - GetLocZ( x[0], y[0] ), 0.00 )
    
    set x1[0] = GetCorX( x1[0] )
    set y1[0] = GetCorY( y1[0] )
    
    call SetUnitX( B.eye, x1[0] )
    call SetUnitY( B.eye, y1[0] )
    call SetUnitFlyHeight( B.eye, z1[0] - GetLocZ( x1[0], y1[0] ), 0.00 )
    
    if A.time >= 1.00 then
        call PauseTimer( A.t )
        
        call KillUnit( A.eye )
        call KillUnit( B.eye )
        
        set A.v[3].z = GetUnitFacing( A.caster )
        
        set A.eye = CreateUnit( A.p, 'u003', A.v[3].x, A.v[3].y, A.v[3].z )
        call UnitAddAbility( A.eye, 'Arav' )
        call SetUnitX( A.eye, A.v[3].x )
        call SetUnitY( A.eye, A.v[3].y )
        call SetUnitFlyHeight( A.eye, 80.00, 0.00 )
        call KillUnit( A.eye )
        
        set A.eye = CreateUnit( A.p, 'u004', A.v[3].x, A.v[3].y, A.v[3].z )
        call UnitAddAbility( A.eye, 'Arav' )
        call SetUnitX( A.eye, A.v[3].x )
        call SetUnitY( A.eye, A.v[3].y )
        call SetUnitFlyHeight( A.eye, 80.00, 0.00 )
        call KillUnit( A.eye )
        
        set A.field = CreateUnit( A.p, 'u006', A.v[3].x, A.v[3].y, A.v[3].z )
        call SetUnitX( A.field, A.v[3].x )
        call SetUnitY( A.field, A.v[3].y )
        call SetUnitAnimation( A.field, "birth" )
        call QueueUnitAnimation( A.field, "stand" )
            
        set A.laserBig = CreateUnit( A.p, 'u007', A.l.x, A.l.y, A.v[3].z )
        call SetUnitX( A.laserBig, A.l.x )
        call SetUnitY( A.laserBig, A.l.y )
        call SetUnitFlyHeight( A.laserBig, 80.00, 0.00 )
        call SetUnitAnimation( A.laserBig, "birth" )
        call QueueUnitAnimation( A.laserBig, "stand" )
        
        set A.v[3].x = A.v[3].x + 150.00 * Cos( A.v[3].z * bj_DEGTORAD )
        set A.v[3].y = A.v[3].y + 150.00 * Sin( A.v[3].z * bj_DEGTORAD )
        
        set A.eye = CreateUnit( A.p, 'u000', A.v[3].x, A.v[3].y, A.v[3].z )
        call SetUnitX( A.eye, A.v[3].x )
        call SetUnitY( A.eye, A.v[3].y )
        call SetUnitFlyHeight( A.eye, 80.00, 0.00 )
        call SetUnitAnimation( A.eye, "birth" )
        call QueueUnitAnimation( A.eye, "stand" )
        
        set i = 0
        loop
            call A.v[i].destroy( )
            call B.v[i].destroy( )
            
            set i = i + 1
            exitwhen i >= 4
        endloop
        
        call B.destroy( )
        
        set A.time = 1.50
        
        call TimerStart( A.t, 0.01, true, function Rotation )
    endif
endfunction

function Spell_Actions takes nothing returns nothing
    local SpellS A = SpellS.create( )
    local SpellS B = SpellS.create( )
    local real a
    
    set A.t = CreateTimer( )
    
    set A.caster = GetTriggerUnit( )
    set A.target = GetSpellTargetUnit( )
    
    set A.p = GetOwningPlayer( A.caster )
    
    set A.l = vector.create( GetUnitX( A.caster ), GetUnitY( A.caster ), 0.00 )
    
    set A.lvl = GetUnitAbilityLevel( A.caster, GetSpellAbilityId( ) )
    
    if A.lvl == 1 then // уровень абилки
        set A.damage = 10.00 // урон
    elseif A.lvl == 2 then
        set A.damage = 25.00
    else
        set A.damage = 40.00
    endif
    
    set A.damagePeriodic = 0.30 // периодичность урона
    
    set A.distance = 900.00 // дистанция
    
    set A.radius = 200.00 // начальный радиус
    set A.radiusEnd = 50.00 // конечный радиус
    
    set A.attackType = null // тип атаки
    set A.damageType = null // тип урона
    set A.weaponType = null // тип оружия (звук)
    
    set A.time = 0.00
    set A.timeMax = 0.80
    
    set A.v[0] = vector.create( A.l.x, A.l.y, 0.00 )
    set A.v[0].z = GetLocZ( A.l.x, A.l.y ) + GetUnitFlyHeight( A.caster ) + 50.00
    
    set a = Atan2( GetUnitY( A.target ) - A.l.y, GetUnitX( A.target ) - A.l.x )
    
    set A.v[1] = vector.create( A.v[0].x - 500.00 * Cos( a - bj_PI * 0.15 ), A.v[0].y - 500.00 * Sin( a - bj_PI * 0.15 ), A.v[0].z + 200.00 )
    set A.v[2] = vector.create( A.v[0].x - 100.00 * Cos( a - bj_PI * 0.15 ), A.v[0].y - 100.00 * Sin( a - bj_PI * 0.15 ), A.v[0].z + 200.00 )
    set A.v[3] = vector.create( A.v[0].x + 125.00 * Cos( a ), A.v[0].y + 125.00 * Sin( a ), 0.00 )
    set A.v[3].z = GetLocZ( A.v[3].x, A.v[3].y ) + 75.00
    
    set A.eye = CreateUnit( A.p, 'u002', A.v[0].x, A.v[0].y, a * bj_RADTODEG )
    call UnitAddAbility( A.eye, 'Arav' )
    call SetUnitX( A.eye, A.v[0].x )
    call SetUnitY( A.eye, A.v[0].y )
    call SetUnitFlyHeight( A.eye, 50.00, 0.00 )
    call SetUnitAnimation( A.eye, "birth" )
    call QueueUnitAnimation( A.eye, "stand" )
    
    set B.v[0] = vector.create( A.l.x, A.l.y, A.l.z )
    set B.v[1] = vector.create( B.v[0].x - 500.00 * Cos( a + bj_PI * 0.15 ), B.v[0].y - 500.00 * Sin( a + bj_PI * 0.15 ), A.v[1].z )
    set B.v[2] = vector.create( B.v[0].x - 100.00 * Cos( a + bj_PI * 0.15 ), B.v[0].y - 100.00 * Sin( a + bj_PI * 0.15 ), A.v[2].z )
    set B.v[3] = vector.create( A.v[3].x, A.v[3].y, A.v[3].z )
    
    set B.eye = CreateUnit( A.p, 'u002', B.v[0].x, B.v[0].y, a * bj_RADTODEG )
    call SetUnitX( B.eye, B.v[0].x )
    call SetUnitY( B.eye, B.v[0].y )
    call UnitAddAbility( B.eye, 'Arav' )
    call SetUnitFlyHeight( B.eye, 50.00, 0.00 )
    call SetUnitAnimation( B.eye, "birth" )
    call QueueUnitAnimation( B.eye, "stand" )
    
    call SaveInteger( H, GetHandleId( A.t ), 0, A )
    call SaveInteger( H, GetHandleId( A.t ), 1, B )
    call TimerStart( A.t, 0.01, true, function CreateEye )
endfunction

//===========================================================================

function Spell_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A000'
endfunction

function InitTrig_Spell takes nothing returns nothing
    set gg_trg_Spell = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Spell, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Spell, Condition( function Spell_Conditions ) )
    call TriggerAddAction( gg_trg_Spell, function Spell_Actions )
    
    set TempUnit = CreateUnit( Player( PLAYER_NEUTRAL_PASSIVE ), 'u008', 0.00, 0.00, 0.00 )
endfunction
endlibrary

library AllGlobalsLib
globals
    constant hashtable H = InitHashtable( )
    constant real UNIT_MAX_COLLISION = 200.00
endglobals

native UnitAlive takes unit id returns boolean

function UnitHasItemOfType takes unit u, integer id returns boolean
    local integer i = 0
    
    loop
        if GetItemTypeId( UnitItemInSlot( u, i ) ) == id then
            return true
        endif
        
        set i = i + 1
        exitwhen i >= bj_MAX_INVENTORY
    endloop
    
    return false
endfunction

struct vector
    real x
    real y
    real z
    
    method length takes nothing returns real
        return SquareRoot( x * x + y * y + z * z )
    endmethod
    
    method normalize takes nothing returns nothing
        local real l = length( )
        
        if l == 0.00 then
            set l = 1.00
        endif
        
        set x = x / l
        set y = y / l
        set z = z / l
    endmethod
    
    static method create takes real x, real y, real z returns thistype
        local thistype this = thistype.allocate( )
        
        set this.x = x
        set this.y = y
        set this.z = z
        
        return this
    endmethod
endstruct

function SetUnitAnimationByIndexTimer takes nothing returns nothing
    local timer t = GetExpiredTimer( )
    local integer i = GetHandleId( t )
    local unit u = LoadUnitHandle( H, i, 0 )
    
    call SetUnitAnimationByIndex( u, LoadInteger( H, i, 1 ) )
    call QueueUnitAnimation( u, "stand ready" )
    call QueueUnitAnimation( u, "stand" )
    
    call FlushChildHashtable( H, i )
    call DestroyTimer( t )
    
    set u = null
    set t = null
endfunction

function SetUnitAnimationByIndexEx takes unit u, integer i returns nothing
    local timer t = CreateTimer( )
    
    call SaveUnitHandle( H, GetHandleId( t ), 0, u )
    call SaveInteger( H, GetHandleId( t ), 1, i )
    
    call TimerStart( t, 0.00, false, function SetUnitAnimationByIndexTimer )
    
    set t = null
endfunction
endlibrary

//===========================================================================
//function InitTrig_AllGlobals takes nothing returns nothing
    //set gg_trg_AllGlobals = CreateTrigger(  )
//endfunction

library SpellLib
globals
    private constant group TempGroup = CreateGroup( )
    private item TempItem = null
    private integer UpgradedKill = 0
    
    constant key SpellUpgrade
endglobals

private struct SpellS
    timer t
    unit caster
    unit dummy
    player p
    effect e = null
    ability abil
    integer attack
    integer upgrade1
    integer upgrade2
    
    vector v
    
    real time
    real timePause
    
    real speed
    
    real radius
    real radiusMax
    
    real damage
    
    attacktype attackType
    damagetype damageType
    weapontype weaponType
endstruct

private function RemoveBuff takes nothing returns nothing
    local timer t = GetExpiredTimer( )
    local integer i = GetHandleId( t )
    
    call DestroyEffect( LoadEffectHandle( H, i, 0 ) )
    call RemoveSavedHandle( H, GetHandleId( LoadUnitHandle( H, i, 1 ) ), SpellUpgrade )
    
    call FlushChildHashtable( H, i )
    call DestroyTimer( t )
    
    set t = null
endfunction

private function Move takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local real x = GetUnitX( A.caster ) + A.speed * A.v.x
    local real y = GetUnitY( A.caster ) + A.speed * A.v.y
    local real x1
    local real y1
    local unit u
    local boolean stunned = GetUnitAbilityLevel( A.caster, 'BPSE' ) > 0
    
    if not stunned then
        if A.timePause > 0.00 then
            set A.timePause = A.timePause - 0.01
            
            if A.timePause <= 0.00 then
                call SetUnitAnimationByIndex( A.caster, 3 ) // анимация второй атаки
            endif
        endif
        
        if A.timePause <= 0.00 then
            call SetItemPosition( TempItem, x, y )
            call SetItemVisible( TempItem, false )
            
            set x1 = GetItemX( TempItem )
            set y1 = GetItemY( TempItem )
            
            if not ( ( x - 1.00 > x1 or x + 1.00 < x1 ) or ( ( y - 1.00 > y1 ) or ( y + 1.00 < y1 ) ) ) then
                call SetUnitX( A.caster, x )
                call SetUnitY( A.caster, y )
            endif
            
            set A.time = A.time - 0.01
        endif
    else
        call SetUnitAnimation( A.caster, "stand" )
    endif
    
    if A.time <= 0.00 or stunned then
        if not stunned then
            set x = x + 100.00 * A.v.x
            set y = y + 100.00 * A.v.y
            
            if A.attack == 0 then
                call DestroyEffect( AddSpecialEffect( "Abilities\\Spells\\Human\\Thunderclap\\ThunderClapCaster.mdl", x, y ) ) // эффект первого удара
                
                // доп. эффект от усиления "Корона титана"
                if A.e != null then
                    set bj_lastCreatedEffect = AddSpecialEffect( "Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y )
                    call BlzSetSpecialEffectScale( bj_lastCreatedEffect, 0.75 )
                    call DestroyEffect( bj_lastCreatedEffect )
                endif
            else
                call DestroyEffect( AddSpecialEffect( "Abilities\\Spells\\Orc\\WarStomp\\WarStompCaster.mdl", x, y ) ) // эффект второго удара
                
                // доп. эффект от усиления "Корона титана"
                if A.e != null then
                    set bj_lastCreatedEffect = AddSpecialEffect( "Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y )
                    call BlzSetSpecialEffectScale( bj_lastCreatedEffect, 1.15 )
                    call DestroyEffect( bj_lastCreatedEffect )
                endif
                
                set A.radius = A.radiusMax
            endif
            
            call GroupEnumUnitsInRange( TempGroup, x, y, A.radius + UNIT_MAX_COLLISION, null )
            
            loop
                set u = FirstOfGroup( TempGroup )
                exitwhen u == null
                call GroupRemoveUnit( TempGroup, u )
                
                if IsUnitInRangeXY( u, x, y, A.radius ) then
                    if UnitAlive( u ) and IsUnitEnemy( u, A.p ) then
                        if A.upgrade1 == 1 and GetRandomInt( 1, 100 ) <= 15 then // шанс заспавнить землетрясение при убийстве (15%)
                            set UpgradedKill = 1
                        endif
                        
                        call UnitDamageTarget( A.caster, u, A.damage, false, false, A.attackType, A.damageType, A.weaponType )
                        
                        set UpgradedKill = 0
                    endif
                endif
            endloop
            
            // плавающий текст
            set bj_lastCreatedTextTag = CreateTextTag( )
            call SetTextTagText( bj_lastCreatedTextTag, I2S( R2I( A.damage ) ) + "!", 12.50 * 0.023 / 10.00 )
            call SetTextTagPosUnit( bj_lastCreatedTextTag, A.caster, 75.00 ) 
            call SetTextTagColor( bj_lastCreatedTextTag, 255, 75, 0, 255 )
            call SetTextTagVelocity( bj_lastCreatedTextTag, 0.00, 0.0355 )
            call SetTextTagPermanent( bj_lastCreatedTextTag, false )
            call SetTextTagLifespan( bj_lastCreatedTextTag, 1.50 )
            call SetTextTagFadepoint( bj_lastCreatedTextTag, 0.00 )
        endif
        
        if A.attack == 0 and not stunned then
            set A.attack = 1
            
            set A.speed = A.speed * 2.00 // ускорение второго удара
            set A.time = 0.70 // время для второго удара
            set A.timePause = 0.50 // пауза перед вторым ударом
        else
            call PauseTimer( A.t )
            call FlushChildHashtable( H, GetHandleId( A.t ) )
            call DestroyTimer( A.t )
            
            call IssueImmediateOrder( A.caster, "stop" )
            
            if A.upgrade2 == 1 and not stunned then
                if GetRandomInt( 1, 100 ) <= 30 then // шанс усилить следующий каст абилки и сбросить перезарядку
                    set A.t = CreateTimer( )
                    
                    call SaveTimerHandle( H, GetHandleId( A.caster ), SpellUpgrade, A.t )
                    
                    call SaveEffectHandle( H, GetHandleId( A.t ), 0, AddSpecialEffectTarget( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile_mini.mdl", A.caster, "weapon" ) ) // эффект усиления
                    call SaveUnitHandle( H, GetHandleId( A.t ), 1, A.caster )
                    
                    call TimerStart( A.t, 5.00, false, function RemoveBuff ) // время усиления
                    
                    if A.e != null then
                        call BlzStartAbilityCooldown( A.abil, BlzGetAbilityCooldown( A.abil ) )
                    endif
                else
                    call BlzStartAbilityCooldown( A.abil, BlzGetAbilityCooldown( A.abil ) )
                endif
            else
                call BlzStartAbilityCooldown( A.abil, BlzGetAbilityCooldown( A.abil ) )
            endif
            
            call PauseUnit( A.caster, false )
            
            if A.e != null then
                call DestroyEffect( A.e )
                set A.e = null
            endif
            
            set A.t = null
            set A.abil = null
            set A.caster = null
            call A.v.destroy( )
            call A.destroy( )
        endif
    endif
endfunction

private function Spell_Actions takes nothing returns nothing
    local SpellS A = SpellS.create( )
    local integer lvl
    local timer t
    
    set A.t = CreateTimer( )
    set A.caster = GetTriggerUnit( )
    set A.p = GetOwningPlayer( A.caster )
    set A.abil = GetSpellAbility( )
    
    set A.v = vector.create( GetSpellTargetX( ) - GetUnitX( A.caster ), GetSpellTargetY( ) - GetUnitY( A.caster ), 0.00 )
    call A.v.normalize( )
    
    set A.damage = BlzGetUnitBaseDamageByIndex( A.caster, 0 ) + BlzGetUnitBonusDamageByIndex( A.caster, 0 )
    
    set lvl = GetUnitAbilityLevel( A.caster, GetSpellAbilityId( ) )
    
    if lvl == 1 then // уровень
        set A.damage = A.damage + 60.00 // доп. урон
    elseif lvl == 2 then
        set A.damage = A.damage + 110.00
    elseif lvl == 3 then
        set A.damage = A.damage + 160.00
    else
        set A.damage = A.damage + 210.00
    endif
        
    set A.radius = 250.00 // радиус первого удара
    set A.radiusMax = 375.00 // радиус второго удара
    
    if UnitHasItemOfType( A.caster, 'afac' ) then // "Сотрясатель земли"
        set A.damage = A.damage * 2.00 // доп. урон (х2)
        set A.upgrade1 = 1
    else
        set A.upgrade1 = 0
    endif
    
    if UnitHasItemOfType( A.caster, 'spsh' ) then // "Корона титана", настройки в других частях кода
        set A.upgrade2 = 1
    else
        set A.upgrade2 = 0
    endif
    
    set t = LoadTimerHandle( H, GetHandleId( A.caster ), SpellUpgrade )
    
    if t != null then
        set A.e = LoadEffectHandle( H, GetHandleId( t ), 0 )
       
        call PauseTimer( t )
        call FlushChildHashtable( H, GetHandleId( t ) )
        call DestroyTimer( t )
        
        call RemoveSavedHandle( H, GetHandleId( A.caster ), SpellUpgrade )
        
        set A.damage = A.damage * 2.50 // дополнительный урон от усиления "Корона титана"
        
        set t = null
    endif
    
    set A.attackType = ATTACK_TYPE_MAGIC
    set A.damageType = DAMAGE_TYPE_DEMOLITION
    set A.weaponType = null
    
    set A.time = 0.40 // время для первого удара
    set A.timePause = 0.00
    set A.speed = 1.20 // скорость перемещения
    set A.attack = 0
    
    call PauseUnit( A.caster, true )
    call SetUnitAnimationByIndexEx( A.caster, 2 ) // анимация первой атаки
    
    call SaveInteger( H, GetHandleId( A.t ), 0, A )
    call TimerStart( A.t, 0.01, true, function Move )
endfunction

private function Damage takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local unit u
    
    call GroupEnumUnitsInRange( TempGroup, A.v.x, A.v.y, A.radius + UNIT_MAX_COLLISION, null )
            
    loop
        set u = FirstOfGroup( TempGroup )
        exitwhen u == null
        call GroupRemoveUnit( TempGroup, u )
        
        if IsUnitInRangeXY( u, A.v.x, A.v.y, A.radius ) then
            if UnitAlive( u ) and IsUnitEnemy( u, A.p ) then
                call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\LordofFlameMissile\\LordofFlameMissile.mdl", u, "chest" ) ) // доп. эффект при попадании
                call UnitDamageTarget( A.caster, u, A.damage, false, false, A.attackType, A.damageType, A.weaponType )
            endif
        endif
    endloop
    
    set A.time = A.time - 1.00 // периодичность урона землетрясения
    
    if A.time <= 0.00 then
        call PauseTimer( A.t )
        call FlushChildHashtable( H, GetHandleId( A.t ) )
        call DestroyTimer( A.t )
        
        call SetUnitAnimation( A.dummy, "death" )
        call UnitRemoveAbility( A.dummy, 'A001' )
        call UnitApplyTimedLife( A.dummy, 'BTLF', 3.00 ) // время анимации смерти
        
        set A.t = null
        set A.caster = null
        set A.dummy = null
        call A.v.destroy( )
        call A.destroy( )
    endif
endfunction

private function Spell_Actions_Death takes nothing returns nothing
    local SpellS A
    
    if UpgradedKill == 1 then
        set A = SpellS.create( )
        
        set A.t = CreateTimer( )
        set A.caster = GetKillingUnit( )
        set A.p = GetOwningPlayer( A.caster )
        set A.v = vector.create( GetUnitX( GetTriggerUnit( ) ), GetUnitY( GetTriggerUnit( ) ), 0.00 )
        
        set A.dummy = CreateUnit( A.p, 'u000', A.v.x, A.v.y, GetRandomReal( 0.00, 360.00 ) ) // даммик землетрясения
        
        call SetUnitX( A.dummy, A.v.x )
        call SetUnitY( A.dummy, A.v.y )
        call SetUnitAnimation( A.dummy, "birth" )
        call QueueUnitAnimation( A.dummy, "stand" )
        
        set A.radius = 300.00 // радиус землетрясения
        set A.damage = 100.00 // урон землетрясения
        set A.attackType = ATTACK_TYPE_MAGIC // тип атаки
        set A.damageType = DAMAGE_TYPE_FIRE // тип урона
        set A.weaponType = null // тип оружия (звук)
        set A.time = 6.00 // время землетрясения
        
        call SaveInteger( H, GetHandleId( A.t ), 0, A )
        call TimerStart( A.t, 1.00, true, function Damage ) // периодичность урона землетрясения
    endif
endfunction

//===========================================================================
private function Spell_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A000' // равкод абилки
endfunction

function InitTrig_Spell takes nothing returns nothing
    local trigger trg = CreateTrigger( )
    
    call TriggerRegisterAnyUnitEventBJ( trg, EVENT_PLAYER_UNIT_DEATH )
    call TriggerAddAction( trg, function Spell_Actions_Death )
    
    set trg = null
    
    set gg_trg_Spell = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Spell, EVENT_PLAYER_UNIT_SPELL_CAST )
    call TriggerAddCondition( gg_trg_Spell, Condition( function Spell_Conditions ) )
    call TriggerAddAction( gg_trg_Spell, function Spell_Actions )
    
    set TempItem = CreateItem( 'spsh', 0.00, 0.00 )
    call SetItemVisible( TempItem, false )
endfunction
endlibrary

library AllGlobalsLib
globals
    constant hashtable H = InitHashtable( )
    constant real UNIT_MAX_COLLISION = 200.00
    
    real MaxX
    real MinX
    real MaxY
    real MinY
endglobals

native UnitAlive takes unit id returns boolean

struct vector
    real x
    real y
    real z
    
    method length takes nothing returns real
        return SquareRoot( x * x + y * y + z * z )
    endmethod
    
    method normalize takes nothing returns nothing
        local real l = length( )
        
        if l == 0.00 then
            set l = 1.00
        endif
        
        set x = x / l
        set y = y / l
        set z = z / l
    endmethod
    
    static method create takes real x, real y, real z returns thistype
        local thistype this = thistype.allocate( )
        
        set this.x = x
        set this.y = y
        set this.z = z
        
        return this
    endmethod
endstruct

function RemoveStun takes nothing returns nothing
    local timer t = GetExpiredTimer( )
    local integer i = GetHandleId( t )
    
    call SetUnitStunned( LoadUnitHandle( H, i, 0 ), false )
    call DestroyEffect( LoadEffectHandle( H, i, 1 ) )
    
    call FlushChildHashtable( H, i )
    call DestroyTimer( t )
    
    set t = null
endfunction

function StunUnit takes unit u, real time, effect e returns nothing
    local timer t = CreateTimer( )
    
    call SetUnitStunned( u, true )
    
    call SaveUnitHandle( H, GetHandleId( t ), 0, u )
    call SaveEffectHandle( H, GetHandleId( t ), 1, e )
    call TimerStart( t, time, false, function RemoveStun )
    
    set t = null
endfunction

//===========================================================================
function InitTrig_AllGlobals takes nothing returns nothing
    //set gg_trg_AllGlobals = CreateTrigger(  )
    local rect r = GetWorldBounds( )
    
    set MaxX = GetRectMaxX( r )
    set MinX = GetRectMinX( r )
    set MaxY = GetRectMaxY( r )
    set MinY = GetRectMinY( r )
    
    call RemoveRect( r )
    set r = null
endfunction
endlibrary

library SpellLib
globals
    private constant group TempGroup = CreateGroup( )
    private item TempItem = null
endglobals

private struct ProjectileS
    timer t
    effect e
    effect e1
    
    real a
    
    vector array v[4]
    vector last
    
    real time
    real timeMax
endstruct

private struct SpellS
    timer t
    unit caster
    unit target
    player p
    vector v
    group g
    integer b
    integer lvl
    
    effect e
    effect e1
    
    real radius
    real damage
    real speed
    real distance
    real time
    
    attacktype attackType
    damagetype damageType
    weapontype weaponType
endstruct

private function Move takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local SpellS B
    local real x = GetUnitX( A.target )
    local real y = GetUnitY( A.target )
    local real x1
    local real y1
    local unit u
    
    if A.b == 1 then
        set A.b = 2
        
        set bj_lastCreatedEffect = AddSpecialEffect( "Abilities\\Weapons\\DemolisherFireMissile\\DemolisherFireMissile.mdl", x, y )
        call SetSpecialEffectZ( bj_lastCreatedEffect, GetSpecialEffectZ( bj_lastCreatedEffect ) + 50.00 )
        call SetSpecialEffectOrientation( bj_lastCreatedEffect, Atan2( A.v.y, A.v.x ) * bj_RADTODEG, -90.00, 0.00 )
        call DestroyEffect( bj_lastCreatedEffect )
        
        set bj_lastCreatedEffect = AddSpecialEffect( "Abilities\\Spells\\Orc\\WarStomp\\WarStompCaster.mdl", x, y )
        call SetSpecialEffectZ( bj_lastCreatedEffect, GetSpecialEffectZ( bj_lastCreatedEffect ) + 50.00 )
        call SetSpecialEffectOrientation( bj_lastCreatedEffect, Atan2( A.v.y, A.v.x ) * bj_RADTODEG, -90.00, 0.00 )
        call DestroyEffect( bj_lastCreatedEffect )
        
        set bj_lastCreatedEffect = AddSpecialEffect( "Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y )
        call SetSpecialEffectZ( bj_lastCreatedEffect, GetSpecialEffectZ( bj_lastCreatedEffect ) + 50.00 )
        call SetSpecialEffectOrientation( bj_lastCreatedEffect, Atan2( A.v.y, A.v.x ) * bj_RADTODEG, -90.00, 0.00 )
        call DestroyEffect( bj_lastCreatedEffect )
        
        call UnitDamageTarget( A.caster, A.target, A.damage, false, false, A.attackType, A.damageType, A.weaponType )
        
        call DestroyEffect( A.e )
        call DestroyEffect( A.e1 )
        
        set A.e = AddSpecialEffectTarget( "Abilities\\Spells\\Human\\FlameStrike\\FlameStrikeEmbers.mdl", A.target, "origin" )
        set A.e1 = AddSpecialEffectTarget( "Abilities\\Spells\\Other\\BreathOfFire\\BreathOfFireDamage.mdl", A.target, "origin" )
    endif
    
    if A.speed > A.distance then
        set A.speed = A.distance
    endif
    
    set x = x + A.speed * A.v.x
    set y = y + A.speed * A.v.y
    
    if A.b >= 2 then
        set A.b = A.b + 1
        
        if A.b == 6 then
            set bj_lastCreatedEffect = AddSpecialEffect( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile_mini.mdl", x, y )
            call SetSpecialEffectZ( bj_lastCreatedEffect, GetSpecialEffectZ( bj_lastCreatedEffect ) + 30.00 )
            call DestroyEffect( bj_lastCreatedEffect )
            
            set A.b = 2
        endif
    endif
    
    set A.distance = A.distance - A.speed
    
    call SetItemPosition( TempItem, x, y )
    call SetItemVisible( TempItem, false )
    
    set x1 = GetItemX( TempItem )
    set y1 = GetItemY( TempItem )
    
    if ( x - 1.00 > x1 or x + 1.00 < x1 ) or ( y - 1.00 > y1 or y + 1.00 < y1 ) then
        set A.distance = 0.00
        call DestroyEffect( AddSpecialEffect( "Abilities\\Spells\\Other\\Volcano\\VolcanoDeath.mdl", x, y ) )
    else
        call SetUnitX( A.target, x )
        call SetUnitY( A.target, y )
    endif
    
    if A.g != null then
        call GroupEnumUnitsInRange( TempGroup, x, y, A.radius + UNIT_MAX_COLLISION, null )
        
        loop
            set u = FirstOfGroup( TempGroup )
            exitwhen u == null
            call GroupRemoveUnit( TempGroup, u )
            
            if not IsUnitInGroup( u, A.g ) and IsUnitInRange( u, A.target, A.radius ) then
                if UnitAlive( u ) and IsUnitEnemy( u, A.p ) then
                    call GroupAddUnit( A.g, u )
                    
                    call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\LordofFlameMissile\\LordofFlameMissile.mdl", u, "chest" ) )
                    call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Spells\\Items\\AIfb\\AIfbSpecialArt.mdl", u, "chest" ) )
                    
                    call UnitDamageTarget( A.caster, A.target, A.damage, false, false, A.attackType, A.damageType, A.weaponType )
                    call UnitDamageTarget( A.caster, u, A.damage, false, false, A.attackType, A.damageType, A.weaponType )
                    call StunUnit( u, 1.00, AddSpecialEffectTarget( "Abilities\\Spells\\Human\\Thunderclap\\ThunderclapTarget.mdl", u, "overhead" ) )
                    
                    set B = SpellS.create( )
                    
                    set B.t = CreateTimer( )
                    set B.target = u
                    set B.v = vector.create( GetUnitX( u ) - x, GetUnitY( u ) - y, 0.00 )
                    call B.v.normalize( )
                    set B.b = 0
                    
                    call SetUnitStunned( u, true )
                    
                    set A.speed = A.speed * 0.90
                    set B.speed = A.speed
                    set B.distance = B.speed / 0.015 * 0.50
                    set A.distance = A.distance * 0.90
                    
                    call SaveInteger( H, GetHandleId( B.t ), 0, B )
                    call TimerStart( B.t, 0.01, false, function Move )
                endif
            endif
        endloop
    endif
    
    if A.distance <= 0.00 or not UnitAlive( A.target ) then
        call PauseTimer( A.t )
        call FlushChildHashtable( H, GetHandleId( A.t ) )
        call DestroyTimer( A.t )
        
        if A.b >= 2 then
            call DestroyEffect( A.e )
            call DestroyEffect( A.e1 )
            set A.e = null
            set A.e1 = null
            
            if UnitAlive( A.target ) then
                call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile.mdl", A.target, "chest" ) )
                call StunUnit( A.target, 1.00 + 1.00 * A.lvl, AddSpecialEffectTarget( "Abilities\\Spells\\Human\\Thunderclap\\ThunderclapTarget.mdl", A.target, "overhead" ) )
            endif
        endif
        
        call SetUnitStunned( A.target, false )
        
        call DestroyGroup( A.g )
        
        set A.t = null
        set A.g = null
        set A.caster = null
        set A.target = null
        call A.v.destroy( )
        call A.destroy( )
    else
        call TimerStart( A.t, 0.01, false, function Move )
    endif
endfunction

private function MoveProjectile takes nothing returns nothing
    local ProjectileS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local real array x
    local real array y
    local real array z
    local integer k = 0
    local integer i
    
    set A.time = A.time + 0.01 / A.timeMax
    
    if A.time >= 0.50 then
        set A.time = A.time + 0.01 / A.timeMax
    endif
    
    if A.time > 1.00 then
        set A.time = 1.00
    endif
    
    loop
        set x[k] = A.v[k].x
        set y[k] = A.v[k].y
        set z[k] = A.v[k].z
        
        set k = k + 1
        exitwhen k >= 4
    endloop
    
    set k = 0
    
    loop
        set i = 0
        
        loop
            set x[i] = ( 1.00 - A.time ) * x[i] + A.time * x[i + 1]
            set y[i] = ( 1.00 - A.time ) * y[i] + A.time * y[i + 1]
            set z[i] = ( 1.00 - A.time ) * z[i] + A.time * z[i + 1]
            
            set i = i + 1
            exitwhen i > 4 - k
        endloop
        
        set k = k + 1
        exitwhen k >= 4 - 1
    endloop
    
    call SetSpecialEffectPositionWithZ( A.e, x[0], y[0], z[0] )
    call SetSpecialEffectPositionWithZ( A.e1, x[0], y[0], z[0] )
    call SetSpecialEffectOrientation( A.e, A.a, Atan2( z[0] - A.last.z, SquareRoot( ( x[0] - A.last.x ) * ( x[0] - A.last.x ) + ( y[0] - A.last.y ) * ( y[0] - A.last.y ) ) ) * bj_RADTODEG, 0.00 )
    call SetSpecialEffectOrientation( A.e1, A.a, Atan2( z[0] - A.last.z, SquareRoot( ( x[0] - A.last.x ) * ( x[0] - A.last.x ) + ( y[0] - A.last.y ) * ( y[0] - A.last.y ) ) ) * bj_RADTODEG, 0.00 )
    
    if A.time >= 1.00 then
        call PauseTimer( A.t )
        call FlushChildHashtable( H, GetHandleId( A.t ) )
        call DestroyTimer( A.t )
        
        call DestroyEffect( A.e )
        call DestroyEffect( A.e1 )
        
        set i = 0
        
        loop
            call A.v[i].destroy( )
            
            set i = i + 1
            exitwhen i >= 4
        endloop
        
        set A.e = null
        set A.e1 = null
        call A.last.destroy( )
        call A.destroy( )
    else
        set A.last.x = x[0]
        set A.last.y = y[0]
        set A.last.z = z[0]
    endif
endfunction

private function Spell_Actions takes nothing returns nothing
    local SpellS A = SpellS.create( )
    local ProjectileS B
    local real x
    local real y
    local real z
    local real a
    local real d
    
    set A.t = CreateTimer( )
    set A.caster = GetTriggerUnit( )
    set A.target = GetSpellTargetUnit( )
    set A.p = GetOwningPlayer( A.caster )
    set A.g = CreateGroup( )
    set A.b = 1
    set A.radius = 64.00 // радиус столкновения
    
    set A.e = AddSpecialEffectTarget( "Abilities\\Weapons\\LavaSpawnMissile\\LavaSpawnMissile.mdl", A.caster, "left hand" )
    set A.e1 = AddSpecialEffectTarget( "Abilities\\Weapons\\LavaSpawnMissile\\LavaSpawnMissile.mdl", A.caster, "right hand" )
    
    set x = GetUnitX( A.caster )
    set y = GetUnitY( A.caster )
    set z = GetAxisZ( x, y ) + GetUnitFlyHeight( A.caster ) + 50.00
    
    set A.v = vector.create( GetUnitX( A.target ) - x, GetUnitY( A.target ) - y, 0.00 )
    set d = A.v.length( )
    call A.v.normalize( )
    set a = Atan2( A.v.y, A.v.x )
    
    set A.lvl = GetUnitAbilityLevel( A.caster, GetSpellAbilityId( ) )
    
    set A.distance = 600.00 + 100.00 * A.lvl // дистанция
    set A.speed = A.distance * 0.015 // скорость
    set A.damage = 25.00 + 10.00 * A.lvl // урон
    
    set A.attackType = ATTACK_TYPE_MAGIC // тип атаки
    set A.damageType = DAMAGE_TYPE_FIRE // тип урона
    set A.weaponType = null // тип оружия (звук)
    
    call SetUnitStunned( A.target, true )
    call GroupAddUnit( A.g, A.caster )
    call GroupAddUnit( A.g, A.target )
    
    call SaveInteger( H, GetHandleId( A.t ), 0, A )
    call TimerStart( A.t, 1.10, false, function Move )
    
    //===
    set B = ProjectileS.create( )
    set B.t = CreateTimer( )
    
    set B.a = a + bj_PI * 0.20
    
    set B.last = vector.create( x, y, z )
    set B.v[0] = vector.create( B.last.x, B.last.y, B.last.z )
    set B.v[1] = vector.create( B.v[0].x - ( d / 2.00 + 500.00 ) * Cos( B.a ), B.v[0].y - ( d / 2.00 + 500.00 ) * Sin( B.a ), B.v[0].z + 300.00 )
    set B.v[2] = vector.create( B.v[0].x + ( d - 200.00 ) * Cos( B.a + bj_PI * 0.10 ), B.v[0].y + ( d - 200.00 ) * Sin( B.a + bj_PI * 0.10 ), B.v[0].z )
    set B.v[3] = vector.create( GetUnitX( A.target ), GetUnitY( A.target ), 0.00 )
    set B.v[3].z = GetAxisZ( B.v[3].x, B.v[3].y ) + 50.00
    
    set B.e = AddSpecialEffect( "units\\human\\phoenix\\phoenix.mdl", B.v[0].x, B.v[0].y )
    call SetSpecialEffectZ( B.e, B.v[0].z )
    call SetSpecialEffectScale( B.e, 0.60 )
    call SetSpecialEffectAlpha( B.e, 155 )
    
    set B.e1 = AddSpecialEffect( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile.mdl", B.v[0].x, B.v[0].y )
     
    set B.a = B.a * bj_RADTODEG
    set B.time = 0.00
    set B.timeMax = 1.50
    
    call SaveInteger( H, GetHandleId( B.t ), 0, B )
    call TimerStart( B.t, 0.01, true, function MoveProjectile )
    
    //===
    set B = ProjectileS.create( )
    set B.t = CreateTimer( )
    
    set B.a = a - bj_PI * 0.20
    
    set B.last = vector.create( x, y, z )
    set B.v[0] = vector.create( B.last.x, B.last.y, B.last.z )
    set B.v[1] = vector.create( B.v[0].x - ( d / 2.00 + 500.00 ) * Cos( B.a ), B.v[0].y - ( d / 2.00 + 500.00 ) * Sin( B.a ), B.v[0].z + 300.00 )
    set B.v[2] = vector.create( B.v[0].x + ( d - 200.00 ) * Cos( B.a - bj_PI * 0.10 ), B.v[0].y + ( d - 200.00 ) * Sin( B.a - bj_PI * 0.10 ), B.v[0].z )
    set B.v[3] = vector.create( GetUnitX( A.target ), GetUnitY( A.target ), 0.00 )
    set B.v[3].z = GetAxisZ( B.v[3].x, B.v[3].y ) + 50.00
    
    set B.e = AddSpecialEffect( "units\\human\\phoenix\\phoenix.mdl", B.v[0].x, B.v[0].y )
    call SetSpecialEffectZ( B.e, B.v[0].z )
    call SetSpecialEffectScale( B.e, 0.60 )
    call SetSpecialEffectAlpha( B.e, 155 )
    
    set B.e1 = AddSpecialEffect( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile.mdl", B.v[0].x, B.v[0].y )
    
    set B.a = B.a * bj_RADTODEG
    set B.time = 0.00
    set B.timeMax = 1.50
    
    call SaveInteger( H, GetHandleId( B.t ), 0, B )
    call TimerStart( B.t, 0.01, true, function MoveProjectile )
endfunction

//===========================================================================
private function Spell_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A000' // равкод
endfunction

function InitTrig_Spell takes nothing returns nothing
    set gg_trg_Spell = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Spell, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Spell, Condition( function Spell_Conditions ) )
    call TriggerAddAction( gg_trg_Spell, function Spell_Actions )
    
    set TempItem = CreateItem( 'spsh', 0.00, 0.00 )
    call SetItemVisible( TempItem, false )
endfunction
endlibrary

library AllGlobalsLib
globals
    constant hashtable H = InitHashtable( )
    constant real UNIT_MAX_COLLISION = 200.00
endglobals

native UnitAlive takes unit id returns boolean

//===========================================================================
//function InitTrig_AllGlobals takes nothing returns nothing
    //set gg_trg_AllGlobals = CreateTrigger(  )
//endfunction
endlibrary

library DamageEventLib
globals
    private constant group TempGroup = CreateGroup( )
endglobals

private struct SpellS
    timer t
    unit caster
    player p
    group g
    real angle
    real speed
endstruct

private function Damage takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local real d = 0.00 
    local real a = GetUnitFacing( A.caster ) * bj_DEGTORAD
    local real x = GetUnitX( A.caster )
    local real y = GetUnitY( A.caster )
    local real x1 = x + 125.00 * Cos( a + bj_PI * 0.30 )
    local real y1 = y + 125.00 * Sin( a + bj_PI * 0.30 )
    local real x2 = x + 125.00 * Cos( a - bj_PI * 0.30 )
    local real y2 = y + 125.00 * Sin( a - bj_PI * 0.30 )
    local unit u
    
    call GroupEnumUnitsInRange( TempGroup, x, y, 400.00 + UNIT_MAX_COLLISION, null )
    
    set A.angle = A.angle + A.speed
    
    loop
        loop
            set u = GroupForEachUnit( TempGroup )
            exitwhen u == null
            
            if not IsUnitInGroup( u, A.g ) then
                if IsUnitInRangeXY( u, x1, y1, 32.00 ) or IsUnitInRangeXY( u, x2, y2, 32.00 )then
                    if UnitAlive( u ) and IsUnitEnemy( u, A.p ) and not IsUnitType( u, UNIT_TYPE_FLYING ) then
                        call GroupAddUnit( A.g, u )
                        call UnitDamageTarget( A.caster, u, 150.00, false, false, null, null, null )
                    endif
                endif
            endif
        endloop
        
        set d = d + 32.00
        exitwhen d >= 200.00
        set x1 = x1 + 32.00 * Cos( a + A.angle )
        set y1 = y1 + 32.00 * Sin( a + A.angle )
        set x2 = x2 + 32.00 * Cos( a - A.angle )
        set y2 = y2 + 32.00 * Sin( a - A.angle )
        
        call DestroyEffect( AddSpecialEffect( "Abilities\\Weapons\\IllidanMissile\\IllidanMissile.mdl", x1, y1 ) )
        call DestroyEffect( AddSpecialEffect( "Abilities\\Weapons\\IllidanMissile\\IllidanMissile.mdl", x2, y2 ) )
    endloop
    
    call GroupClear( TempGroup )
    
    if A.angle * bj_RADTODEG >= 120.00 or not UnitAlive( A.caster ) then
        call PauseTimer( A.t )
        call DestroyTimer( A.t )
        call FlushChildHashtable( H, GetHandleId( A.t ) )
        
        call SetUnitStunned( A.caster, false )
        call DestroyGroup( A.g )
        
        set A.t = null
        set A.g = null
        set A.caster = null
        call A.destroy( )
    else
        call TimerStart( A.t, 0.05, false, function Damage )
    endif
endfunction

private function DamageEvent_Actions takes nothing returns nothing
    local SpellS A
    
    if GetUnitAbilityLevel( GetEventDamageSource( ), 'A000' ) > 0 and GetEventIsAttack( ) and GetRandomInt( 1, 100 ) <= 20 then
        set A = SpellS.create( )
        
        set A.t = CreateTimer( )
        set A.caster = GetEventDamageSource( )
        set A.p = GetOwningPlayer( A.caster )
        set A.g = CreateGroup( )
        set A.angle = 60.00 * bj_DEGTORAD
        set A.speed = 60.00 / 0.75 * 0.05 * bj_DEGTORAD
        
        call SetUnitStunned( A.caster, true )
        call SetUnitAnimation( A.caster, "spell slam" )
        call QueueUnitAnimation( A.caster, "stand" )
        
        call SaveInteger( H, GetHandleId( A.t ), 0, A )
        call TimerStart( A.t, 0.25, false, function Damage )
    endif
endfunction

//===========================================================================
function InitTrig_DamageEvent takes nothing returns nothing
    set gg_trg_DamageEvent = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_DamageEvent, EVENT_PLAYER_UNIT_DAMAGED )
    call TriggerAddAction( gg_trg_DamageEvent, function DamageEvent_Actions )
endfunction
endlibrary

library AllGlobalsLib
globals
    constant hashtable H = InitHashtable( )
    constant real UNIT_MAX_COLLISION = 200.00
endglobals

native UnitAlive takes unit id returns boolean

struct vector
    real x
    real y
    real z
    
    method length takes nothing returns real
        return SquareRoot( x * x + y * y + z * z )
    endmethod
    
    method normalize takes nothing returns nothing
        local real l = length( )
        
        if l == 0.00 then
            set l = 1.00
        endif
        
        set x = x / l
        set y = y / l
        set z = z / l
    endmethod
    
    static method create takes real x, real y, real z returns thistype
        local thistype this = thistype.allocate( )
        
        set this.x = x
        set this.y = y
        set this.z = z
        
        return this
    endmethod
endstruct
endlibrary

//===========================================================================
//function InitTrig_AllGlobals takes nothing returns nothing
    //set gg_trg_AllGlobals = CreateTrigger(  )
//endfunction

library SpellLib
globals
    private constant group TempGroup = CreateGroup( )
endglobals

private struct SpellS
    timer t
    unit caster
    effect e
    player p
    vector v
    vector l
    integer i
    group g
    
    real damage
    real speed
    real distance
    real time
    real radius
    handlelist effectList
    
    attacktype attackType
    damagetype damageType
    weapontype weaponType
endstruct

private function Move takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    
    if A.speed > A.distance then
        set A.speed = A.distance
    endif
    
    set A.distance = A.distance - A.speed
    
    set A.l.x = A.l.x + A.speed * A.v.x
    set A.l.y = A.l.y + A.speed * A.v.y
    set A.l.z = A.l.z + A.speed * A.v.z
    
    call SetSpecialEffectPositionWithZ( A.e, A.l.x, A.l.y, A.l.z )
    
    if A.distance <= 0.00 or A.l.z <= GetAxisZ( A.l.x, A.l.y ) + 32.00 then
        call PauseTimer( A.t )
        call FlushChildHashtable( H, GetHandleId( A.t ) )
        call DestroyTimer( A.t )
        
        call DestroyEffect( A.e )
        
        if A.i == 1 then
            call SetSpecialEffectVisible( A.e, false )
            
            set A.e = AddSpecialEffect( "Abilities\\Spells\\Orc\\MirrorImage\\MirrorImageCaster.mdl", A.l.x, A.l.y )
            call SetSpecialEffectZ( A.e, A.l.z )
            call SetSpecialEffectOrientation( A.e, Atan2( A.v.y, A.v.x ) * bj_RADTODEG, 45.00, 0.00 )
            call SetSpecialEffectTimeScale( A.e, 2.00 )
            call DestroyEffect( A.e )
        endif
        
        set A.e = null
        set A.t = null
        call A.l.destroy( )
        call A.v.destroy( )
        call A.destroy( )
    endif
endfunction

private function Damage takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local unit u
    
    loop
        set u = FirstOfGroup( A.g )
        exitwhen u == null
        call GroupRemoveUnit( A.g, u )
        
        call SetUnitStunned( u, false )
        call SetUnitTimeScale( u, 1.00 )
        call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile.mdl", u, "chest" ) )
        
        call UnitDamageTarget( A.caster, u, A.damage, false, false, A.attackType, A.damageType, A.weaponType )
    endloop
    
    call PauseUnit( A.caster, false )
    
    set A.l.z = GetUnitFacing( A.caster ) * bj_DEGTORAD
    set A.l.x = A.l.x + 100.00 * Cos( A.l.z )
    set A.l.y = A.l.y + 100.00 * Sin( A.l.z )
    
    call DestroyEffect( A.e )
    
    set A.e = AddSpecialEffect( "Objects\\Spawnmodels\\Other\\NeutralBuildingExplosion\\NeutralBuildingExplosion.mdl", A.l.x, A.l.y )
    call DestroyEffect( A.e )
    
    loop
        call DestroyEffect( HandleListGetEffectByIndex( A.effectList, A.i ) )
        
        set A.i = A.i - 1
        exitwhen A.i < 0
    endloop
    
    call HandleListDestroy( A.effectList )
    
    call PauseTimer( A.t )
    call FlushChildHashtable( H, GetHandleId( A.t ) )
    call DestroyTimer( A.t )
    
    call DestroyGroup( A.g )
    
    set A.g = null
    set A.t = null
    set A.e = null
    set A.caster = null
    call A.l.destroy( )
    call A.destroy( )
endfunction

private function AddHitEffect takes nothing returns nothing
    local integer i = GetRandomInt( 0, 5 )
    
    if i == 0 then
        call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\LavaSpawnMissile\\LavaSpawnMissile.mdl", GetEnumUnit( ), "chest" ) )
    elseif i == 1 then
        call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\LavaSpawnMissile\\LavaSpawnMissile.mdl", GetEnumUnit( ), "head" ) )
    elseif i == 2 then
        call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\LavaSpawnMissile\\LavaSpawnMissile.mdl", GetEnumUnit( ), "left hand" ) )
    elseif i == 3 then
        call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\LavaSpawnMissile\\LavaSpawnMissile.mdl", GetEnumUnit( ), "right hand" ) )
    elseif i == 4 then
        call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\LavaSpawnMissile\\LavaSpawnMissile.mdl", GetEnumUnit( ), "left foot" ) )
    else
        call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Weapons\\LavaSpawnMissile\\LavaSpawnMissile.mdl", GetEnumUnit( ), "right foot" ) )
    endif
endfunction

private function SpawnEffects takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local SpellS B = SpellS.create( )
    local real a = GetRandomReal( -bj_PI, bj_PI )
    local integer i
    
    call ForGroup( A.g, function AddHitEffect )
    
    set B.t = CreateTimer( )
    
    set B.i = 0
    set B.l = vector.create( A.l.x + GetRandomReal( A.radius * 0.80, A.radius ) * Cos( a ), A.l.y + GetRandomReal( A.radius * 0.80, A.radius ) * Sin( a ), A.l.z + GetRandomReal( -900.00, 0.00 ) )
    set a = a + bj_PI + GetRandomReal( -bj_PI, bj_PI ) * 0.25
    set B.v = vector.create( A.l.x + GetRandomReal( A.radius * 0.80, A.radius ) * Cos( a ), A.l.y + GetRandomReal( A.radius * 0.80, A.radius ) * Sin( a ), 0.00 )
    set B.v.z = GetAxisZ( B.v.x, B.v.y ) + B.l.z + GetRandomReal( -400.00, 100.00 )
    set B.v.x = B.v.x - B.l.x
    set B.v.y = B.v.y - B.l.y
    set B.v.z = B.v.z - B.l.z
    
    set B.e = AddSpecialEffect( "Abilities\\Spells\\Orc\\MirrorImage\\MirrorImageCaster.mdl", B.l.x, B.l.y )
    call SetSpecialEffectZ( B.e, B.l.z )
    call SetSpecialEffectOrientation( B.e, Atan2( B.v.y, B.v.x ) * bj_RADTODEG, Atan2( B.v.z, SquareRoot( B.v.x * B.v.x + B.v.y * B.v.y ) ) * bj_RADTODEG, 0.00 )
    call SetSpecialEffectTimeScale( B.e, 2.00 )
    call DestroyEffect( B.e )
    
    set B.e = AddSpecialEffect( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile_mini.mdl", B.l.x, B.l.y )
    call SetSpecialEffectZ( B.e, B.l.z )
    call SetSpecialEffectOrientation( B.e, Atan2( B.v.y, B.v.x ) * bj_RADTODEG, Atan2( B.v.z, SquareRoot( B.v.x * B.v.x + B.v.y * B.v.y ) ) * bj_RADTODEG, 0.00 )
    call SetSpecialEffectAnimation( B.e, "stand" )
    call SetSpecialEffectScale( B.e, 0.50 )
    
    set B.distance = B.v.length( )
    call B.v.normalize( )
    
    set B.speed = B.distance / 0.15 * 0.01
    
    call SaveInteger( H, GetHandleId( B.t ), 0, B )
    call TimerStart( B.t, 0.01, true, function Move )
    
    set A.time = A.time - 0.05
    
    if A.time <= 0.00 then
        call SetUnitFlyHeight( A.caster, 0.00, 0.00 )
        call ShowUnit( A.caster, true )
        call SetUnitAnimation( A.caster, "stand ready" )
        call QueueUnitAnimationByIndex( A.caster, 3 )
        call QueueUnitAnimation( A.caster, "stand" )
        
        set i = 6
    
        loop
            set B = SpellS.create( )
            set B.t = CreateTimer( )
            
            set B.i = 0
            set B.l = vector.create( A.l.x + A.radius * Cos( a ), A.l.y + A.radius * Sin( a ), A.l.z )
            set B.v = vector.create( A.l.x, A.l.y, 0.00 )
            set B.v.z = GetAxisZ( B.v.x, B.v.y ) + 100.00
            set B.v.x = B.v.x - B.l.x
            set B.v.y = B.v.y - B.l.y
            set B.v.z = B.v.z - B.l.z
            
            set B.e = AddSpecialEffect( "Abilities\\Spells\\Orc\\MirrorImage\\MirrorImageCaster.mdl", B.l.x, B.l.y )
            call SetSpecialEffectZ( B.e, B.l.z )
            call SetSpecialEffectOrientation( B.e, Atan2( B.v.y, B.v.x ) * bj_RADTODEG, Atan2( B.v.z, SquareRoot( B.v.x * B.v.x + B.v.y * B.v.y ) ) * bj_RADTODEG, 0.00 )
            call SetSpecialEffectTimeScale( B.e, 2.00 )
            call DestroyEffect( B.e )
            
            set B.e = AddSpecialEffect( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile_mini.mdl", B.l.x, B.l.y )
            call SetSpecialEffectZ( B.e, B.l.z )
            call SetSpecialEffectOrientation( B.e, Atan2( B.v.y, B.v.x ) * bj_RADTODEG, Atan2( B.v.z, SquareRoot( B.v.x * B.v.x + B.v.y * B.v.y ) ) * bj_RADTODEG, 0.00 )
            call SetSpecialEffectAnimation( B.e, "stand" )
            call SetSpecialEffectScale( B.e, 0.50 )
            
            set B.distance = B.v.length( )
            call B.v.normalize( )
            
            set B.speed = B.distance / 0.20 * 0.01
            
            call SaveInteger( H, GetHandleId( B.t ), 0, B )
            call TimerStart( B.t, 0.01, true, function Move )
            
            set i = i - 1
            exitwhen i <= 0
            set a = a - bj_PI / 6.00 * 2.00
        endloop
        
        call DestroyEffect( A.e )
        
        set A.e = AddSpecialEffect( "Abilities\\Spells\\Orc\\MirrorImage\\MirrorImageCaster.mdl", A.l.x, A.l.y )
        call SetSpecialEffectYaw( A.e, GetUnitFacing( A.caster ) )
        call DestroyEffect( A.e )
        
        set A.e = AddSpecialEffectTarget( "Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile.mdl", A.caster, "weapon" )
        
        if GetLocalPlayer( ) == A.p then
            call ClearSelection( )
            call SelectUnit( A.caster, true )
        endif
        
        call TimerStart( A.t, 2.10, false, function Damage )
    endif
endfunction

private function JumpClones takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    local SpellS B
    local integer i = 6
    local real a = -bj_PI
    local unit u
    
    call GroupEnumUnitsInRange( TempGroup, A.l.x, A.l.y, A.radius, null )
    
    loop
        set u = FirstOfGroup( TempGroup )
        exitwhen u == null
        call GroupRemoveUnit( TempGroup, u )
        
        if IsUnitInRangeXY( u, A.l.x, A.l.y, A.radius + UNIT_MAX_COLLISION ) then
            if UnitAlive( u ) and IsUnitEnemy( u, A.p ) then
                call GroupAddUnit( A.g, u )
                call SetUnitStunned( u, true )
                call SetUnitTimeScale( u, 0.00 )
            endif
        endif
    endloop
    
    call PauseUnit( A.caster, true )
    call ShowUnit( A.caster, false )
    
    set A.l.z = GetAxisZ( A.l.x, A.l.y ) + GetUnitFlyHeight( A.caster )
    
    set A.e = AddSpecialEffect( "Abilities\\Spells\\Orc\\MirrorImage\\MirrorImageCaster.mdl", A.l.x, A.l.y )
    call SetSpecialEffectZ( A.e, A.l.z )
    call SetSpecialEffectYaw( A.e, GetUnitFacing( A.caster ) )
    call DestroyEffect( A.e )
    
    set A.e = AddSpecialEffect( "Abilities\\Spells\\Orc\\Bloodlust\\BloodlustTarget.mdl", A.l.x, A.l.y )
    call SetSpecialEffectZ( A.e, A.l.z / 2.00 )
    call SetSpecialEffectTimeScale( A.e, 0.10 )
    call SetSpecialEffectScale( A.e, 50.00 )
    call SetSpecialEffectAlpha( A.e, 175 )
    
    loop
        set B = SpellS.create( )
        
        set B.t = CreateTimer( )
        
        set B.l = vector.create( A.l.x, A.l.y, A.l.z )
        set B.v = vector.create( Cos( a ), Sin( a ), Cos( bj_PI * 0.50 ) )
        
        set B.i = 1
        set B.speed = 40.00
        set B.distance = A.radius
        
        set B.e = AddSpecialEffect( "Abilities\\Spells\\Orc\\MirrorImage\\MirrorImageMissile.mdl", B.l.x, B.l.y )
        call SetSpecialEffectZ( B.e, B.l.z )
        call SetSpecialEffectOrientation( B.e, a * bj_RADTODEG, 45.00, 0.00 )
        
        call SaveInteger( H, GetHandleId( B.t ), 0, B )
        call TimerStart( B.t, 0.01, true, function Move )
        
        set i = i - 1
        exitwhen i <= 0
        set a = a - bj_PI / 5.00
    endloop
    
    set A.radius = A.radius * 1.50
    set A.time = 2.00
    call TimerStart( A.t, 0.05, true, function SpawnEffects )
endfunction

private function Jump takes nothing returns nothing
    local SpellS A = LoadInteger( H, GetHandleId( GetExpiredTimer( ) ), 0 )
    
    if UnitAddAbility( A.caster, 'Arav' ) then
        call UnitRemoveAbility( A.caster, 'Arav' )
    endif
    
    call SetUnitFlyHeight( A.caster, 800.00, 800.00 / 0.20 )
    
    call DestroyEffect( A.e )
    
    set A.e = AddSpecialEffect( "Units\\NightElf\\Wisp\\WispExplode.mdl", A.l.x, A.l.y )
    call SetSpecialEffectAnimationOffsetPercent( A.e, 0.20 )
    call SetSpecialEffectTimeScale( A.e, 3.00 )
    call DestroyEffect( A.e )
    
    call TimerStart( A.t, 0.20, false, function JumpClones )
endfunction

private function Spell_Actions takes nothing returns nothing
    local SpellS A = SpellS.create( )
    local integer i
    local real a = GetRandomReal( -bj_PI, bj_PI )
    
    set A.t = CreateTimer( )
    set A.caster = GetTriggerUnit( )
    set A.p = GetOwningPlayer( A.caster )
    set A.l = vector.create( GetUnitX( A.caster ), GetUnitY( A.caster ), 0.00 )
    set A.g = CreateGroup( )
    set A.e = AddSpecialEffect( "Abilities\\Spells\\Undead\\DarkRitual\\DarkRitualTarget.mdl", A.l.x, A.l.y )
    call SetSpecialEffectScale( A.e, 2.00 )
    
    set A.damage = 200.00 // урон
    set A.radius = 600.00 // радиус
    set A.attackType = ATTACK_TYPE_CHAOS // тип атаки
    set A.damageType = DAMAGE_TYPE_SONIC // тип урона
    set A.weaponType = null
    
    set A.effectList = HandleListCreate( )
    
    set A.i = 60 // количество эффектов отображения радиуса
    set i = A.i
    
    loop
        set bj_lastCreatedEffect = AddSpecialEffect( "Abilities\\Spells\\Orc\\Bloodlust\\BloodlustTarget.mdl", A.l.x + A.radius * Cos( a ), A.l.y + A.radius * Sin( a ) )
        call SetSpecialEffectZ( bj_lastCreatedEffect, GetSpecialEffectZ( bj_lastCreatedEffect ) + 50.00 )
        call HandleListAddHandle( A.effectList, bj_lastCreatedEffect )
        
        set i = i - 1
        exitwhen i <= 0
        set a = a + bj_PI / A.i * 2.00
    endloop
    
    call SaveInteger( H, GetHandleId( A.t ), 0, A )
    call TimerStart( A.t, 1.50, false, function Jump )
endfunction

//===========================================================================
private function Spell_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A000'
endfunction

function InitTrig_Spell takes nothing returns nothing
    set gg_trg_Spell = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Spell, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Spell, Condition( function Spell_Conditions ) )
    call TriggerAddAction( gg_trg_Spell, function Spell_Actions )
endfunction
endlibrary

function SetBonusArmorNegative takes unit u, integer value returns nothing
    local integer i = udg_BDMax
    
    loop
        exitwhen i <= 0
        
        if udg_BDValue[i] <= value then
            call UnitAddAbility( u, udg_BDAbil[i] )
        
            set value = value - udg_BDValue[i]
        else
            call UnitRemoveAbility( u, udg_BDAbil[i] )
        endif
        
        set i = i - 1
    endloop
endfunction

function RemoveDebuff takes nothing returns nothing
    local timer t = GetExpiredTimer( )
    local integer i = GetHandleId( t )
    local unit u = LoadUnitHandle( udg_H, i, 0 )
    
    call UnitRemoveAbility( u, 'A009' )
    call UnitRemoveAbility( u, 'B000' )
    call SetBonusArmorNegative( u, 0 )
        
    call RemoveSavedInteger( udg_H, GetHandleId( u ), 0 )
    
    call FlushChildHashtable( udg_H, i )
    call DestroyTimer( t )
    
    set u = null
    set t = null
endfunction

function Trig_EventDamage_Actions takes nothing returns nothing
    local unit damaged
    local timer t
    local integer i
    local integer stack
    
    if GetUnitAbilityLevel( GetTriggerUnit( ), 'Bspo' ) > 0 then
        set damaged = GetTriggerUnit( )
        call UnitRemoveAbility( damaged, 'Bspo' )
        
        set t = LoadTimerHandle( udg_H, GetHandleId( damaged ), 0 )
        
        if t == null then
            set t = CreateTimer( )
            
            call SaveTimerHandle( udg_H, GetHandleId( damaged ), 0, t )
            call UnitAddAbility( damaged, 'A009' )
            call SaveUnitHandle( udg_H, GetHandleId( t ), 0, damaged )
        endif
        
        set i = GetHandleId( t )
        set stack = LoadInteger( udg_H, i, 1 ) + 1
        
        call SetUnitAbilityLevel( damaged, 'A009', stack )
        call SetBonusArmorNegative( damaged, IMaxBJ( 1, R2I( GetHeroLevel( GetEventDamageSource( ) ) * 0.10 ) ) * stack )
        
        if stack < udg_BDMax then
            call SaveInteger( udg_H, i, 1, stack )
        else
            call IssueTargetOrder( udg_TempUnit, "soulburn", damaged )
        endif
        
        call TimerStart( t, 5.00, false, function RemoveDebuff )
        
        set t = null
        set damaged = null
    endif
endfunction

//===========================================================================
function InitTrig_EventDamage takes nothing returns nothing
    set gg_trg_EventDamage = CreateTrigger(  )
    call TriggerAddAction( gg_trg_EventDamage, function Trig_EventDamage_Actions )
    set udg_TempUnit = CreateUnit( Player( PLAYER_NEUTRAL_PASSIVE ), 'u000', 0.00, 0.00, 0.00 )
endfunction