function EndThread takes nothing returns nothing
    call I2R(1 / 0)
endfunction

function ErrorOccurred takes string message, string errorcode returns nothing
    if GameIsRunning then
        set GameIsRunning = false
        // Create error file
        call PreloadGenClear()
        call PreloadMessage("Error: " + message)
        call PreloadGenEnd("WispTD\\Errors\\" + errorcode + ".txt")
        // Update UI end environment
        call ClearSelection()
        call StopMusic(false)
        call ClearMapMusic()
        call StopAmbientSounds()
        call MultiboardSetTitleText(Board, "An internal error occurred")
        // Disable triggers and end game
        call DisableTriggers()
        call TriggerExecute(gg_trg_ErrorOccurred)
        call FinishGameNoCheck("An internal error occurred. Error code: " + Color.Errors.hex + errorcode + "|r.", FinishGameTime_Error)
    endif
    call EndThread()
endfunction

function Trig_ErrorOccured_Actions takes nothing returns nothing
    local integer i = 0
    loop
        exitwhen i > Players.top
        call Players[i].errorOccured()
        set i = i + 1
    endloop
    call PlayingPlayers.reset()
endfunction

function InitTrig_ErrorOccurred takes nothing returns nothing
    set gg_trg_ErrorOccurred = CreateTrigger()
    call TriggerAddAction(gg_trg_ErrorOccurred, function Trig_ErrorOccured_Actions)
endfunction

    method errorOccured takes nothing returns nothing
        call field.errorOccured()
        if playing then
            set playing = false
            set inGame = false
            call showGrid(false)
            call GroupEnumUnitsInRect(ProxyGroup, field.playerarea, LightDeleteUnits)
        endif
    endmethod

//! textmacro CustomArray takes name, type, size, index, err
struct $name$
    private $type$ array objects[$size$]
    readonly integer top = -1
    
    method operator [] takes integer i returns $type$
        return objects[i]
    endmethod
    
    method addToArray takes $type$ obj returns nothing
        if obj.$index$ == -1 then
            set top = top + 1
            static if ErrorDetectionEnabled_CustomArray and $err$ then
                if top == $size$ then
                    call ErrorOccurred("not enough cells in $name$ " + I2S(this) + ". Current amount of cells is " + I2S($size$), "$name$Cells")
                endif
            endif
            set objects[top] = obj
            set obj.$index$ = top
            //call DebugMsg("$type$ " + I2S(obj) + " with index " + I2S(top) + " is added to $name$.")
        else
            call ErrorOccurred("an attempt of $type$ " + I2S(obj) + " to be added to $name$ " + I2S(this) + " second time", "$name$Add")
        endif
    endmethod
    
    method deleteFromArray takes $type$ obj returns nothing
        local integer i = obj.$index$
        if i > -1 then
            if top > i then
                set objects[i] = objects[top]
                set objects[i].$index$ = i
            endif
            set top = top - 1
            set obj.$index$ = -1
            //call DebugMsg("$type$ " + I2S(obj) + " with index " + I2S(i) + " is removed from $name$.")
        else
            call ErrorOccurred("an attempt of $type$ " + I2S(obj) + " to be deleted from $name$ " + I2S(this) + " second time", "$name$Delete")
        endif
    endmethod
    
    method reset takes nothing returns nothing
        set this.top = -1
    endmethod
endstruct
//! endtextmacro