function BuilderAbilityEffect takes unit b, integer id returns nothing
    local CustomPlayer p = GetCustomPlayer(GetOwningPlayer(b))
    // SelectBarracks Faction 1
    if id == p.faction1.builder_icon0 then
        if p.isLocalPlayer then
            call ClearSelection()
            call SelectUnit(p.barracks, true)
        endif
        if p.current_barracks_faction != p.faction1 then
            call p.swapFactionInBarracks()
        endif
        return
    endif
    // SelectBarracks Faction 2
    if id == p.faction2.builder_icon1 then
        if p.isLocalPlayer then
            call ClearSelection()
            call SelectUnit(p.barracks, true)
        endif
        if p.current_barracks_faction != p.faction2 then
            call p.swapFactionInBarracks()
        endif
        return
    endif
    // SelectAltar
    if (id == p.herodata.builder_icon or id == BuilderSelectAltar) and p.isLocalPlayer then
        call ClearSelection()
        call SelectUnit(p.altar, true)
    endif
endfunction

function BarracksAbilityEffect takes unit b, integer id returns nothing
    local CustomPlayer p = GetCustomPlayer(GetOwningPlayer(b))
    // MinionSpawn
    if Minion.hire(p, id) then
        return
    endif
    // SelectBlacksmith
    if id == BarracksSelectBlacksmith then
        if p.isLocalPlayer then
            call ClearSelection()
            call SelectUnit(p.blacksmith, true)
        endif
        if p.current_barracks_faction != p.current_blacksmith_faction then
            call p.swapFactionInBlacksmith()
        endif
        return
    endif
    // SelectAltar
    if id == BarracksSelectAltar and p.isLocalPlayer then
        call ClearSelection()
        call SelectUnit(p.altar, true)
        return
    endif
    // SelectCapm
    if id == BarracksSelectCamp and p.isLocalPlayer then
        call ClearSelection()
        call SelectUnit(p.merccamp, true)
        return
    endif
    // SwapFaction
    if id == SwapFaction then
        call p.swapFactionInBarracks()
    endif
endfunction

function BlacksmithAbilityEffect takes unit b, integer id returns nothing
    local CustomPlayer p = GetCustomPlayer(GetOwningPlayer(b))
    // MinionUpgrades
    if Minion.makeUpgrade(p, id) then
        return
    endif
    // SwapFaction
    if id == SwapFaction then
        call p.swapFactionInBlacksmith()
        return
    endif
    // MHU
    if id == BlacksmithMHU then
        call UpgradeMinionHealth(p)
    endif
endfunction

function AltarAbilityEffect takes unit b, integer id returns nothing
    local CustomPlayer p = GetCustomPlayer(GetOwningPlayer(b))
    // Hero selection
    if id == p.faction1.herodata.altar_icon0 then
        call UnitRemoveAbility(b, p.faction2.herodata.altar_icon1)
        call p.addHero(p.faction1.herodata)
        return
    endif
    if id == p.faction2.herodata.altar_icon1 then
        call UnitRemoveAbility(b, p.faction1.herodata.altar_icon0)
        call p.addHero(p.faction2.herodata)
        return
    endif
    // Ability selection
    if p.changeHeroAbilityByRawCode(id) then
        return
    endif
    // Upgrades
    if Minion.makeUpgrade(p, id) then
        return
    endif
endfunction

function MercCampAbilityEffect takes unit b, integer id returns nothing
   call Minion.hire(GetCustomPlayer(GetOwningPlayer(b)), id)
endfunction

function TowerAbilityEffect takes Tower caster, integer id, integer target returns nothing
    // Sell
    if id == TowerAbilSell or id == TowerAbilDestroy then
        call caster.sell()
        return
    endif
    // Upgrade
    if id == TowerAbilUpgrade then
        call Tower.upgradeTower(caster)
        return
    endif
    // ExpGenerator
    if id == AbilExpGenerator.AbilSelectTower then
        call AbilExpGenerator.selectTowerAll(caster.abil, target)
    endif
endfunction

function Trig_PlayerAbilityEffect_Actions takes nothing returns nothing
    local integer id = GetSpellAbilityId()
    local unit u = GetSpellAbilityUnit()
    local integer caster = GetUnitUserData(u)
    local integer target = GetUnitUserData(GetSpellTargetUnit())
    local integer T = GetUnitTypeId(u)
    if T == BuilderId then
        call BuilderAbilityEffect(u, id)
    elseif T == BarracksId then
        call BarracksAbilityEffect(u, id)
    elseif T == BlacksmithId then
        call BlacksmithAbilityEffect(u, id)
    elseif T == AltarId then
        call AltarAbilityEffect(u, id)
    elseif T == MercCampId then
        call MercCampAbilityEffect(u, id)
    elseif IsUnitTower(u) then
        call TowerAbilityEffect(caster, id, target)
    endif
    set u = null
endfunction

function InitTrig_PlayerAbilityEffect takes nothing returns nothing
    set gg_trg_PlayerAbilityEffect = CreateTrigger()
    call TriggerAddAction(gg_trg_PlayerAbilityEffect, function Trig_PlayerAbilityEffect_Actions)
endfunction

function TowerAbilityEndcast takes Tower caster, integer id returns nothing
    local TowerAbility abil = caster.abil
    // FocusedAttack
    if abil.getType() == AbilFocusedAttack.typeid then
        call AbilFocusedAttack.returnNormalProjectile(abil, id)
        return
    endif
    // ChillingAttack
    if abil.getType() == AbilChillingAttack.typeid then
        call AbilChillingAttack.returnNormalProjectile(abil, id)
        return
    endif
    // LightningAttack
    if abil.getType() == AbilLightningAttack.typeid then
        call AbilLightningAttack.returnNormalProjectile(abil, id)
        return
    endif
    // ExpGenerator
    if abil.getType() == AbilExpGenerator.typeid then
        call AbilExpGenerator.changeModeAll(abil, id)
    endif
endfunction

function MinionAbilityEndcast takes Minion m, integer id returns nothing
    // Stop
    if id == MinionAbilStop then
        call Minion.stopOrder(m.owner)
        return
    endif
    // Sell
    if id == MinionAbilSell or id == MinionAbilUnchallenge then
        call m.sell()
    endif
endfunction

function Trig_PlayerAbilityEndcast_Actions takes nothing returns nothing
    local integer id = GetSpellAbilityId()
    local unit u = GetSpellAbilityUnit()
    local integer caster = GetUnitUserData(u)
    if IsUnitTower(u) or IsUnitTowerAttacker(u) then
        call TowerAbilityEndcast(caster, id)
    elseif IsUnitMinion(u) then
        call MinionAbilityEndcast(caster, id)
    endif
    set u = null
endfunction

function InitTrig_PlayerAbilityEndcast takes nothing returns nothing
    set gg_trg_PlayerAbilityEndcast = CreateTrigger()
    call TriggerAddAction(gg_trg_PlayerAbilityEndcast, function Trig_PlayerAbilityEndcast_Actions)
endfunction