native UnitAlive takes unit u returns boolean
//! zinc
    library MinerMiner {
        group g = CreateGroup();
        unit u;
        integer uid, action, itid, did;
        rect r = Rect(0, 0, 0, 0);
        real ux, uy, dx, dy;
        item it;
        destructable d, dt;

        function distance(destructable d, unit u) -> real {
            real dx = GetUnitX(u) - GetDestructableX(d);
            real dy = GetUnitY(u) - GetDestructableY(d);
            return dx * dx + dy * dy;
        }

        function onInit() {
            trigger t = CreateTrigger();
            TriggerRegisterTimerEventPeriodic(t, .5);
            TriggerAddAction( t, function() {
                integer i = 0;
                for (0 <= i < bj_MAX_PLAYER_SLOTS) {
                    GroupEnumUnitsOfPlayer(g, Player(i), null);
                    ForGroup(g, function() {
                        u = GetEnumUnit();
                        uid = GetUnitTypeId(u);
                        ux = GetUnitX(u);
                        uy = GetUnitY(u);
                        if (!UnitAlive(u)) {
                            return;
                        }
                        // Баф на юните при вкл.скила
                        if (GetUnitAbilityLevel(u, 'BUF1') == 0 && GetUnitAbilityLevel(u, 'BUF2') == 0 && GetUnitAbilityLevel(u, 'BUF3') == 0) {
                            return;
                        }
                        if (GetUnitCurrentOrder(u) != 0) {
                            return;
                        }
                        action = 0;

                        //  около 20 юнитов
                        if(uid == 'UNT1' || uid == 'UNT2' || uid == 'UNT3') {
                            SetRect(r, ux - 300, uy - 300, ux + 300, uy + 300);
                            EnumItemsInRect(r, null, function() {
                                it = GetEnumItem();
                                itid = GetItemTypeId(it);
                                //  Только 2 предмета не ITEM_TYPE_POWERUP
                                if (GetItemType(it) != ITEM_TYPE_POWERUP && itid != 'I000' && itid != 'I002') {
                                    return;
                                }
                                if(UnitInventorySize(u) - UnitInventoryCount(u) <= 0) {
                                    return;
                                }
                                IssueTargetOrder(u, "smart", it);
                                action = 2;                            
                            });
                        }

                        if (action == 0) {
                            SetRect(r, ux - 700, uy - 700, ux + 700, uy + 700);
                            dt = null;
                            EnumDestructablesInRect(r, null, function() {
                                d = GetEnumDestructable();
                                did = GetDestructableTypeId(d);
                                dx = GetDestructableX(d);
                                dy = GetDestructableY(d);

                                //  Ненужный объект
                                if (GetDestructableLife(d) <= 0 && did != 'B003') {
                                    return;
                                }

                                if (dt == null || distance(d, u) < distance(dt, u)) {
                                    action = 1;
                                    dt = d;
                                }
                            });
                        }

                        if (action == 0) {
                            IssuePointOrder(u, "move", GetRandomReal(ux - 300, ux + 300), GetRandomReal(uy - 300, uy + 300));
                        }

                        if (action == 1) {
                            if (distance(dt, u) < 62500) {
                                IssueTargetOrder( u, "attack", dt);
                            } else {
                                IssuePointOrder(u, "move", GetDestructableX(dt), GetDestructableY(dt));
                            }
                        }
                    });
                }
            });
            t = null;
        }
    }
//! endzinc