// For SetUnitFlags0x20 (0x20)
	constant integer UNIT_HIDDEN 				= 0x1
	constant integer UNIT_LOCUST_NONSELECTABLE = 0x2 
	constant integer UNIT_NONSELECTABLE = 0x4
	constant integer UNIT_INVULNERABLE 			= 0x8
	constant integer UNIT_VISIBLED_TO_ALL 		= 0x10
	constant integer UNIT_AUTOATTACK_DISABLED=0x10000000
	
	
	// For SetUnitFlags0x5C (0x5C)
	//flag 0x4 causes fatal if any damage received
	//flag 0x40 stands for red flash, but doesn't directly calls it
	constant integer UNIT_DEAD = 0x100
	//like dead hero, provides no vision, cant be selected, enemies doesn't flee when attacked by this flag
	constant integer UNIT_MINIMAP_ICON_HIDE		= 0x80000
	constant integer UNIT_MINIMAP_ICON_TAVERN	= 0x40000
	constant integer UNIT_MINIMAP_ICON_GOLD		= 0x20000
	constant integer UNIT_MINIMAP_SHAREVISIBLE	= 0x10000
	constant integer UNIT_STUNNED= 0x100000
	constant integer UNIT_INVISIBLED 			= 0x1000000
	constant integer UNIT_HIDDEN_PANEL=0x4000000//same as 0x2000000, differences are unknown
	constant integer UNIT_HAS_FLYING_VISION= 0x20000000
	constant integer UNIT_ILLUSION=0x40000000

function RequiemFilter takes nothing returns boolean
    set bj_lastFilterUnit = GetFilterUnit( )
    return IsUnitEnemy( bj_lastFilterUnit, bj_groupEnumOwningPlayer )and not( IsUnitDead( bj_lastFilterUnit )or IsUnitType( bj_lastFilterUnit, UNIT_TYPE_STRUCTURE )or IsUnitWard( bj_lastFilterUnit )or IsUnitInGroup( bj_lastFilterUnit, LoadGroupHandle( HashData, GetHandleId( GetExpiredTimer( ) ), 0 ) )or GetUnitAbilityLevel( bj_lastFilterUnit, 'A04R' ) > 0 )
endfunction

function Timer_SoulCrippile_Expires takes nothing returns nothing
    local timer t = GetExpiredTimer( )
    local integer id = GetHandleId( t )
    local group grp = LoadGroupHandle( HashData, id, 0 )
    local player pl = LoadPlayerHandle( HashData, id, 1 )
    local real cx = LoadReal( HashData, id, 2 )
    local real cy = LoadReal( HashData, id, 3 )
    local real rad = LoadReal( HashData, id, 4 )
    local integer level = LoadInteger( HashData, id, 5 )
    local unit enemy
    if rad > 1024.00 then
        call ReleaseTimer( t )
        call FlushChildHashtable( HashData, id )
        call NSI( grp )
        call DestroyTimer( t )
    else
        set rad = rad + 32.00
        set bj_groupEnumOwningPlayer = pl
        call GroupClear( bj_TempGroup )
        call GroupEnumUnitsInRange( bj_TempGroup, cx, cy, rad, Condition( function RequiemFilter ) )
        call GroupAddGroup( bj_TempGroup, grp )
        loop
            set enemy = FirstOfGroup( bj_TempGroup )
            exitwhen( enemy == null )
            call GroupRemoveUnit( bj_TempGroup, enemy )
            set bj_lastCreatedUnit = CreateUnit( GetOwningPlayer( enemy ), DUMMY, GetUnitX( enemy ), GetUnitY( enemy ), GetUnitFacing( enemy ) )
            call SetUnitPathing( bj_lastCreatedUnit, false )
            call UnitApplyTimedLife( bj_lastCreatedUnit, 'BTLF', 3.00 )
            call SetUnitX( bj_lastCreatedUnit, GetUnitX( enemy ) )
            call SetUnitY( bj_lastCreatedUnit, GetUnitY( enemy ) )
            call UnitAddAbility( bj_lastCreatedUnit, 'A0HH' )
            call SetUnitAbilityLevel( bj_lastCreatedUnit, 'A0HH', level )
            call UnitShareVision( enemy, pl, true )
            call IssueTargetOrder( bj_lastCreatedUnit, "cripple", enemy )
            call UnitShareVision( enemy, pl, false )
        endloop
        set enemy = null
        call SaveReal( HashData, id, 4, rad )
    endif
    set grp = null
    set t = null
endfunction

function DarkSouls takes unit fiend, integer soulcount returns boolean
    local real cx = GetUnitX( fiend )
    local real cy = GetUnitY( fiend )
    local player pl = GetOwningPlayer( fiend )
    local real facing
    local real dx
    local real dy
    local integer lines = 0
    local integer nIndex = 1
    local integer level = GetUnitAbilityLevel( fiend, 'A29J' )
    local timer t
    if soulcount < 1 or level == 0 then
        return false
    endif
    set lines = IMaxBJ( R2I( soulcount / 2 ), 1 )
    loop
        exitwhen nIndex > lines
        set facing = ( I2R( nIndex ) * ( 360.00 / lines ) )
        set bj_lastCreatedUnit = CreateUnit( pl, DUMMY, cx, cy, facing )
        set facing = facing * bj_DEGTORAD
        set dx = cx + 64.00 * Cos( facing )
        set dy = cy + 64.00 * Sin( facing )
        call SetUnitPathing( bj_lastCreatedUnit, false )
        call SetUnitX( bj_lastCreatedUnit, cx )
        call SetUnitY( bj_lastCreatedUnit, cy )
        call UnitApplyTimedLife( bj_lastCreatedUnit, 'BTLF', 2.00 )
        call UnitAddAbility( bj_lastCreatedUnit, 'A0HG' )
        call SetUnitAbilityLevel( bj_lastCreatedUnit, 'A0HG', level )
        if not IssuePointOrder( bj_lastCreatedUnit, "carrionswarm", dx, dy ) then
            call IssuePointOrder( bj_lastCreatedUnit, "carrionswarm", cx + 256.00 * Cos( facing ), cy + 256.00 * Sin( facing ) )
        endif
        set nIndex = nIndex + 1
    endloop
    set t = NewTimer( )
    set nIndex = GetHandleId( t )
    call SaveGroupHandle( HashData, nIndex, 0, NTI( ) )
    call SavePlayerHandle( HashData, nIndex, 1, pl )
    call SaveReal( HashData, nIndex, 2, cx )
    call SaveReal( HashData, nIndex, 3, cy )
    call SaveReal( HashData, nIndex, 4, 64.00 )
    call SaveInteger( HashData, nIndex, 5, level )
    call TimerStart( t, 0.03125, true, function Timer_SoulCrippile_Expires )
    set t = null
    return true
endfunction